Question

目前我的代码中有一个2D数组

integer, allocatable :: elements(:,:)

并定义一些常量

integer, parameter :: TYP = 1
integer, parameter :: WIDTH = 2
integer, parameter :: HEIGHT = 3
! ...
integer, parameter :: NUM_ENTRIES = 10

并分配类似

的内容

allocate(elements(NUM_ENTRIES,10000))

所以我可以访问像

这样的元素

write(*,*) elements(WIDTH,100) ! gives the width of the 100th element

现在我想要的不仅是整数，还有每种元素的混合类型。所以我定义了派生类型

type Element
    logical active
    integer type
    real width
    ! etc
end type

并使用Elements数组

type(Element), allocatable :: elements(:)

使用2d数组版本，我可以调用一个子程序来告诉它使用哪个条目。 E.g。

subroutine find_average(entry, avg)
    integer, intent(in) :: entry   
    real, intent(out) :: avg
    integer i, 
    real s

    s = 0
    do i = lbound(elements,1), ubound(elements,1)
        if (elements(TYP,i) .gt. 0) s = s + elements(entry,i)
    end do
    avg = s/(ubound(elements,1)-lbound(elements,1))
end subroutine

所以我可以call find_average(HEIGHT)找到平均身高或通过WIDTH来获得平均宽度。（而且我的子程序比找到平均高度或宽度做更高级的事情，这只是一个例子。）

问题：如何使用不同的类型（与派生类型一样），还可以重用我的函数来处理不同的条目（如示例子例程中所示）？

Answer 1

对于数组的情况，你可以传入单个参数数组（i），而不是传入参数array和index i。当您切换到派生类型时，类似地，您可以传入variable_of_type％元素，而不是传入整个variable_of_type，并以某种方式指示过程应该处理哪个子元素。如果代码需要针对不同类型的元素（例如，逻辑，整数，实数）不同，那么您可以为每个元素编写特定的过程，但是通过通用接口块以通用名称调用。编译器必须能够通过参数的某些特性来区分通用接口块的过程，这里是它们的类型。对于其中区别特征是数组排名的代码示例，请参阅how to write wrapper for 'allocate'

编辑：示例代码。这样做你想要的吗？

module my_subs

   implicit none

   interface my_sum
      module procedure sum_real, sum_int
   end interface my_sum

contains

subroutine sum_real (array, tot)
   real, dimension(:), intent (in) :: array
   real, intent (out) :: tot
   integer :: i

   tot = 1.0
   do i=1, size (array)
      tot = tot * array (i)
   end do
end subroutine sum_real

subroutine sum_int (array, tot)
   integer, dimension(:), intent (in) :: array
   integer, intent (out) :: tot
   integer :: i

   tot = 0
   do i=1, size (array)
      tot = tot + array (i)
   end do
end subroutine sum_int

end module my_subs


program test_dt

use my_subs

implicit none

type my_type
   integer weight
   real length
end type my_type

type (my_type), dimension (:), allocatable :: people
type (my_type) :: answer

allocate (people (2))

people (1) % weight = 1
people (1) % length = 1.0
people (2) % weight = 2
people (2) % length = 2.0

call my_sum ( people (:) % weight, answer % weight )
write (*, *)  answer % weight

call my_sum ( people (:) % length, answer % length )
write (*, *)  answer % length

end program test_dt

派生类型数组：选择条目

1 个答案: