Question

我正在编写此代码以解决我必须从文件中读取整数并将其存储到数组中以执行其他操作的问题。到目前为止，我已经能够从文件中读取并将它们存储到缓冲区中。

#### Read Data from File
li $v0, 14              # system call for read from file
move $a0, $s6     
la $a1, buffer          # address of buffer from which to read
li $a2, 1000            # hardcoded buffer length
syscall                 # read from file

当我这样做时：它成功显示文件的内容，这些内容在不同的行上是整数。

li $v0, 4           # syscall for printing a string
la $a0, buffer          # load read data in $a0
syscall

我陷入困境，我必须将缓冲区中的这些整数存储到数组中。这是怎么做到的？

Answer 1

你没有给我们提供很多信息，所以我假设你的文件看起来像这样：

1234 523 54326 7131

（它可以是行分隔的，概念是相同的）

将数字读入字符串后，必须将其解析为整数。然后将其存储在整数数组中。你的数组应该是这样的：

        .align 2    # word-aligned
array:  .space 40    # a word array of 10 elements

要将字符串解析为整数，您可以从C中取出概念，其中包含atoi（），如下所示：

#
#  int atoi ( const char *str );
#
#  Parse the cstring str into an integral value
#
atoi:
    or      $v0, $zero, $zero   # num = 0
    or      $t1, $zero, $zero   # isNegative = false
    lb      $t0, 0($a0)
    bne     $t0, '+', .isp      # consume a positive symbol
    addi    $a0, $a0, 1
.isp:
    lb      $t0, 0($a0)
    bne     $t0, '-', .num
    addi    $t1, $zero, 1       # isNegative = true
    addi    $a0, $a0, 1
.num:
    lb      $t0, 0($a0)
    slti    $t2, $t0, 58        # *str <= '9'
    slti    $t3, $t0, '0'       # *str < '0'
    beq     $t2, $zero, .done
    bne     $t3, $zero, .done
    sll     $t2, $v0, 1
    sll     $v0, $v0, 3
    add     $v0, $v0, $t2       # num *= 10, using: num = (num << 3) + (num << 1)
    addi    $t0, $t0, -48
    add     $v0, $v0, $t0       # num += (*str - '0')
    addi    $a0, $a0, 1         # ++num
    j   .num
.done:
    beq     $t1, $zero, .out    # if (isNegative) num = -num
    sub     $v0, $zero, $v0
.out:
    jr      $ra         # return

（就像C atoi（）函数一样，它没有错误检查机制，你可能想添加它。）

从文件中解析每个单独的数字（通过传递给atoi（））并将其作为整数存储在数组中。

MIPS：将整数数据存储到文件中

1 个答案: