Question

下面的

是document_1.xml

<products>
    <product>
        <name>Pen</name>
        <Quantity>10</Quantity>
    </product>
    <product>
        <name>Pencil</name>
        <Quantity>20</Quantity>
    </product>
    <product>
        <name>Bag</name>
        <Quantity>25</Quantity>
    </product>
</products>

和document_2.xml是

<products>
    <product>
        <name>Pen</name>
        <Quantity>30</Quantity>
    </product> 

    <product>
        <name>Pencil</name>
        <Quantity>5</Quantity>
    </product>
    <product>
        <name>Bag</name>
        <Quantity>2</Quantity>
    </product>
</products>

和document.xml是

<products>
</products>

以下是我的xsl，我曾经加入document_1.xml和document_2.xml加入document.xml

    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ns="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="ns">
<xsl:output method="xml" indent="yes"/>

<xsl:key name="kProdByName" match="product" use="name"/>

<xsl:template match="products">
<xsl:copy>

<xsl:variable name="msNodes">
    <xsl:apply-templates select="document('document_1.xml')/*/product|document('document_2.xml')/*/product">
    <xsl:sort select="Quantity" data-type="number"/>
    </xsl:apply-templates> 
</xsl:variable>

<xsl:apply-templates select="ns:node-set($msNodes)/product [generate-id() =  generate-id(key('kProdByName', name)[1])  ]"/>

</xsl:copy>
</xsl:template>


<xsl:template match="product">
   <product>
    <xsl:for-each select="key('kProdByName', name)">
      <xsl:if test="position() = 1">
        <xsl:copy-of select="node()"/>
      </xsl:if>
    </xsl:for-each>
   </product>
</xsl:template>

</xsl:stylesheet>

以上xsl的输出是

<products>
    <product>
        <name>Bag</name>
        <Quantity>2</Quantity>
    </product>
    <product>
        <name>Pencil</name>
        <Quantity>5</Quantity>
    </product>
    <product>
        <name>Pen</name>
        <Quantity>10</Quantity>
    </product>
    </product>

这里我需要使用xslt 1.0

从输出中删除<Quantity>节点

我需要输出如下

<products>
    <product>
        <name>Bag</name>
    </product>
    <product>
        <name>Pencil</name>
    </product>
    <product>
        <name>Pen</name>
    </product>
    </product>

Answer 1

匹配Quantity的空模板应该这样做：

<xsl:template match="Quantity"/>

Answer 2

尝试添加

<xsl:template match="/products/product/Quantity"/>

Answer 3

<强>替换：

<xsl:copy-of select="node()"/>

<强>与：

<xsl:copy-of select="node()[not(self::Quantity)]"/>

或者，如果Quantity不是product的直接子项，而是后代，则将以上内容替换为：

<xsl:apply-templates mode="skipQuantity"/>

并添加以下模板：

<xsl:template match="node()|@*" mode="skipQuantity">
  <xsl:copy>
    <xsl:apply-templates select="node()|@*" mode="skipQuantity"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="Quantity" mode="skipQuantity"/>

请注意：

虽然这些更改产生了新的想要结果，但很多以前的处理变得不必要，可以完全省略。

转换可以大大简化为（没有找到最小数量，只根据产品名称进行分组）：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:ns="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="ns">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:key name="kProdByName" match="product" use="name"/>

    <xsl:template match="products">
        <xsl:copy>
            <xsl:variable name="msNodes">
                    <xsl:copy-of select=
                    "document('document_1.xml')/*/product
                |
                     document('document_2.xml')/*/product"/>
            </xsl:variable>

            <xsl:apply-templates select=
             "ns:node-set($msNodes)/product
                  [generate-id()
                  =
                   generate-id(key('kProdByName', name)[1])
                   ]"/>
        </xsl:copy>
    </xsl:template>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="Quantity"/>
</xsl:stylesheet>

如何使用xslt从文档方法中删除节点

3 个答案: