Question

我从我的xml得到一些整数，我希望得到介于1和得到的数字之间的所有数字。

我想将这些数字作为列名插入。

有可能吗？

谢谢。

Answer 1

<强>予。 XSLT 2.0解决方案：

 <xsl:sequence select="1 to $N"/>

<强> II。 XSLT 1.0 DVC解决方案

@nd（使用原始递归）的答案很好。

但是，如果要生成长度足够大（1000或更多）的数字序列，则由于递归过深，原始递归通常会因堆栈溢出而异常结束。

DVC（Divide and Conquer）方法可用于避免任何实际情况下的调用堆栈溢出：

<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output method="text"/>

     <xsl:template match="/">
      <xsl:call-template name="displayNumbers">
        <xsl:with-param name="pStart" select="1"/>
        <xsl:with-param name="pEnd" select="1000000"/>
      </xsl:call-template>
     </xsl:template>

     <xsl:template name="displayNumbers">
      <xsl:param name="pStart"/>
      <xsl:param name="pEnd"/>

      <xsl:if test="not($pStart > $pEnd)">
       <xsl:choose>
        <xsl:when test="$pStart = $pEnd">
          <xsl:value-of select="$pStart"/>
          <xsl:text>&#xA;</xsl:text>
        </xsl:when>
        <xsl:otherwise>
          <xsl:variable name="vMid" select=
           "floor(($pStart + $pEnd) div 2)"/>
          <xsl:call-template name="displayNumbers">
           <xsl:with-param name="pStart" select="$pStart"/>
           <xsl:with-param name="pEnd" select="$vMid"/>
          </xsl:call-template>
          <xsl:call-template name="displayNumbers">
           <xsl:with-param name="pStart" select="$vMid+1"/>
           <xsl:with-param name="pEnd" select="$pEnd"/>
          </xsl:call-template>
        </xsl:otherwise>
       </xsl:choose>
      </xsl:if>
     </xsl:template>
</xsl:stylesheet>

当此转换应用于任何XML文档（未使用）时，它会输出一到一百万的数字。此转换期间调用堆栈的最大部分仅为19（log2（N））。

<强> III。非递归XSLT 1.0解决方案：

如果要生成的数字序列的长度不是太大（更确切地说，不超过XML文档中可用节点的数量（例如XSLT样式表本身））），然后我们可以使用非递归解决方案，称为Piez method ：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:variable name="vDoc" select="document('')"/>
 <xsl:variable name="vNodes" select=
 "$vDoc//node() | $vDoc//@* | $vDoc//namespace::*"/>

 <xsl:template match="/">
     <xsl:for-each select="$vNodes[not(position() > 40)]">
      <xsl:value-of select="position()"/>
      <xsl:text>&#xA;</xsl:text>
     </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于任何XML文档（未使用）时，它会生成1到40之间的数字：

Answer 2

首先提出建议：通常这样的问题表明事情应该以更加XSLT的方式以不同的方式完成 - 例如通过匹配源XML树并使用position()获取当前节点索引的模板。

但是如果你需要，你可以得到介于1和任意数字之间的所有整数。但是，由于无法在XSLT中重新分配变量，标准方法是使用递归：

<xsl:template name="counter">
  <xsl:param name="current"/>
  <xsl:param name="max"/>
  <xsl:if test=" $max >= $current">
    <!-- do whatever you want to do with the current item here -->
    <th><xsl:value-of select="$current"/></th>

    <!-- increase the counter for the recursive call -->
    <xsl:call-template name="counter">
      <xsl:with-param name="current" select="$current + 1"/>
      <xsl:with-param name="max" select="$max"/>
    </xsl:call-template>
  </xsl:if>
</xsl:template>

然后，使用起始值和最大数字调用递归模板：

<xsl:call-template name="counter">
  <xsl:with-param name="current" select="1"/>
  <xsl:with-param name="max" select="$gotten-number"/>
</xsl:call-template>

for xslt页面中的循环

2 个答案: