Question

我是XSLT的新手，面临一个典型的问题。下面是问题的详细信息。我需要来自ItemB的结果（很多次是ItemB），其中属性BNum id与ANum id匹配，并且输出将是属性VAR1 id和ANum id的串联。

环绕对象是我面临的主要问题。

示例输入：

<?xml version="1.0" encoding="UTF-8"?>
<myData>
<ItemA>
   <VAR1 id="1234">
     <ANum id = "3333"/>
     <ANum id = "5555"/>
     <ANum id = "6666"/>
   </VAR1>
   <VAR1 id="7B62">
     <ANum id = "4444"/>
   </VAR1>
</ItemA>
<ItemB>
   <BNum id = "6666"/>
</ItemB>
<ItemB>
   <BNum id = "4444"/>
</ItemB>
</myData>

所需的输出：

 <?xml version="1.0" encoding="UTF-8"?>
    <result>
     <ItemC>
       <CNum id = "1234-6666"/>
      </ItemC>
     <ItemC>
       <CNum id = "7B62-4444"/>
     </ItemC>
    </result>

我尝试了以下代码-

<?xml version='1.0' ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/">
        <result>
            <xsl:for-each select="myData/ItemB">
                <ItemC>
                    <CNum>
                        <xsl:value-of select="BNum"/>
                        <xsl:if test="../ItemA/VAR1/ANum/@id = BNum/@id">
                            <xsl:attribute name="id">
                                <xsl:value-of select="concat(../ItemA/VAR1/@id,'-',BNum/@id)"/>
                            </xsl:attribute>
                        </xsl:if>
                    </CNum>
                </ItemC>
            </xsl:for-each>
        </result>
    </xsl:template>
</xsl:stylesheet>

我得到的输出为-

<?xml version="1.0" encoding="UTF-8"?>
<result>
 <ItemC>
   <CNum id = "1234-6666"/>
  </ItemC>
 <ItemC>
   <CNum id = "1234-4444"/>
 </ItemC>
</result>

ItemC的最后一个值是错误的，需要更正它。

Answer 1

交叉引用最好使用key处理。然后问题变得不那么重要了：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="v1" match="VAR1" use="ANum/@id" />

<xsl:template match="/myData">
    <result>
        <xsl:for-each select="ItemB/BNum">
            <ItemC>
                <CNum id="{key('v1', @id)/@id}-{@id}"/>
            </ItemC>
        </xsl:for-each>
    </result>
</xsl:template>

</xsl:stylesheet>

注意：要了解这一点，您可能还需要了解Attribute Value Templates。

XSLT嵌套用于循环

1 个答案: