Question

我正在尝试创建一个函数，它将一个可变函数作为一个参数，即

func :: (a -> ... -> a) -> a

我该如何做到这一点？

我已经阅读了polyvariadic functions并且我确信Oleg already did it，但是我试图将这种模式应用于具有可变参数函数的函数作为参数。特别是Olegs方法似乎只适用于格拉斯哥扩展，我希望该解决方案适用于纯Haskell 98（如Text.Printf那样）。

我问的原因是我正在尝试构建一个以布尔函数作为参数的函数，并检查它是否是重言式，即

isTautology :: (Bool -> ... -> Bool) -> Bool

以便输入：

isTautology (\x -> x && not x)
isTautology (\x y -> x && y || not y)

我的问题是我继续阅读有关诀窍是使返回类型成为一个类型变量（因此它可以是结果或其他函数），但我的返回类型是固定的（Bool）。

Answer 1

诀窍是创建一个类型类，您将为其定义函数实例，以及返回类型的实例。它是Bool的事实根本不是问题。

我们正在尝试编写一个采用可变参数并返回Bool的函数，因此我们将定义一个具有此类函数的类型类。

class Stmt a where
    tautology :: a -> Bool

接下来，我们为可变参数函数的返回类型定义一个实例。在这种情况下，那是Bool。

-- A Bool is a tautology if it's True.
instance Stmt Bool where
    tautology = id

关键部分是采用Bool参数的函数的下一个实例，其返回类型是我们类中的某种类型。这样，如果函数接受多个参数，则该实例将被多次应用。

-- A function is a tautology if it always returns a tautology.
instance Stmt b => Stmt (Bool -> b) where
    tautology f = tautology (f True) && tautology (f False)

以这种方式编写需要FlexibleInstances，因为第二个实例头中的Bool。为了对纯Haskell 98做同样的事情，我们需要使用适当约束的类型变量。例如，我们可以使用Bounded和Enum（Bool都有实例），或者您可以创建自己的类来构建适当的输入。

instance (Enum a, Bounded a, Stmt b) => Stmt (a -> b) where
    tautology f = all (tautology . f) [minBound .. maxBound]

我们已经完成了。我们试一试：

> tautology $ \x y -> (not x && not y) == not (x && y)
False
> tautology $ \x y -> (not x && not y) == not (x || y)
True

如何编写一个以可变函数作为参数的Haskell函数

1 个答案: