Question

我试图在列表中找到一些线索，但我不能，如果我问一个重复的主题，那就很抱歉

我是PERL初学者，我正在尝试在PERL中编写一个程序，它接受两个DNA序列，计算第二个序列的反向并找到它们之间的最大互补区域，即：

输入：

CGTAAATCTATCTT
CATGCGTCTTTACG

输出：

CGTAAATCTATCTT
GCATTT--------

我找到第二个序列的反向没有问题，但是我在PERL中的编程技巧还不成熟。我是否需要组合使用foreach循环？

Answer 1

这对你有用吗？

#!/usr/bin/perl
use warnings;
use strict;

sub complement {
    $_[0] =~ y/CGAT/GCTA/;
    return $_[0];
}

sub match {
    my ($s1, $s2) = @_;
    $s2 = reverse $s2;
    complement $s2;
    print "$s1\n";
    my $s2l = length $s2;
    for (my $length = $s2l; $length; $length--) { # start from the longest possible substring
        for my $start (0 .. $s2l - $length) {     # starting position of the matching substring
            my $substr = substr $s2, $start, $length;
            my $pos = index $s1, $substr;
            if ($pos + 1) {
                return ('-' x $pos) . complement "$substr" . ('-' x ($s2l - $length - $pos));
            }
        }
    }
}

print match('CGTAAATCTATCTT',
            'CATGCGTCTTTACG')
    ,"\n";

Answer 2

也许这就是你想要的（粗略地）：

#!/usr/bin/env perl
use strict;
use warnings;
die unless @ARGV == 2 && length $ARGV[0] == length $ARGV[1];
my @seq1 = split //, $ARGV[0];
my @seq2 = split //, reverse $ARGV[1];
my @comp;
for my $n (0..@seq1-1) {
    if   ( ($seq1 [$n] eq 'A' && $seq2 [$n] eq 'T') 
        || ($seq1 [$n] eq 'T' && $seq2 [$n] eq 'A') 
        || ($seq1 [$n] eq 'G' && $seq2 [$n] eq 'C') 
        || ($seq1 [$n] eq 'C' && $seq2 [$n] eq 'G') ) {
        push @comp, $seq2[$n];
    }
    else {
        push @comp, '-';
    }
}
print @seq1, "\n", @comp, "\n";

......运行时：

# ./compseq CGTAAATCTATCTT CATGCGTCTTTACG
CGTAAATCTATCTT
GCATTT------A-

比对2个DNA序列并找到互补区域

2 个答案: