Question

在重复列表中查找句点的最佳方法是什么？

例如：

a = {4, 5, 1, 2, 3, 4, 5, 1, 2, 3, 4, 5, 1, 2}

重复{4, 5, 1, 2, 3}，其余{4, 5, 1, 2}匹配，但不完整。

算法应该足够快以处理更长的情况，如下所示：

b = RandomInteger[10000, {100}];
a = Join[b, b, b, b, Take[b, 27]]

如果没有像上面那样的重复模式，算法应返回$Failed。

Answer 1

请参阅有关其工作原理的代码中的评论。

(* True if a has period p *)
testPeriod[p_, a_] := Drop[a, p] === Drop[a, -p]

(* are all the list elements the same? *)
homogeneousQ[list_List] := Length@Tally[list] === 1
homogeneousQ[{}] := Throw[$Failed] (* yes, it's ugly to put this here ... *)

(* auxiliary for findPeriodOfFirstElement[] *)
reduce[a_] := Differences@Flatten@Position[a, First[a], {1}]

(* the first element occurs every ?th position ? *)
findPeriodOfFirstElement[a_] := Module[{nl},
  nl = NestWhileList[reduce, reduce[a], ! homogeneousQ[#] &];
  Fold[Total@Take[#2, #1] &, 1, Reverse[nl]]
  ]

(* the period must be a multiple of the period of the first element *)
period[a_] := Catch@With[{fp = findPeriodOfFirstElement[a]},
   Do[
    If[testPeriod[p, a], Return[p]],
    {p, fp, Quotient[Length[a], 2], fp}
    ]
   ]

请询问findPeriodOfFirstElement[]是否不清楚。我独立完成了这项工作（为了好玩！），但现在我看到原理与Verbeia的解决方案相同，除了Brett指出的问题是固定的。

我正在测试

b = RandomInteger[100, {1000}];
a = Flatten[{ConstantArray[b, 1000], Take[b, 27]}];

（注意低整数值：在同一时期内会有很多重复元素*）

编辑：根据Leonid下面的评论，通过使用专门为列表编译的自定义位置功能，可以实现2-3倍的加速（在我的机器上约为2.4倍）整数：

(* Leonid's reduce[] *)

myPosition = Compile[
  {{lst, _Integer, 1}, {val, _Integer}}, 
  Module[{pos = Table[0, {Length[lst]}], i = 1, ctr = 0}, 
    For[i = 1, i <= Length[lst], i++, 
      If[lst[[i]] == val, pos[[++ctr]] = i]
    ]; 
    Take[pos, ctr]
  ], 
  CompilationTarget -> "C", RuntimeOptions -> "Speed"
]

reduce[a_] := Differences@myPosition[a, First[a]]

在快速测试中编译testPeriod可以进一步加快20％的速度，但我相信这将取决于输入数据：

Clear[testPeriod]
testPeriod = 
 Compile[{{p, _Integer}, {a, _Integer, 1}}, 
  Drop[a, p] === Drop[a, -p]]

Answer 2

如果您没有噪音，上述方法会更好。如果您的信号只是近似值，那么傅立叶变换方法可能会有用。我将用“参数化”设置来说明，其中基本信号的重复长度和数量，尾随部分的长度以及噪声扰动的界限都是可以使用的变量。

noise = 20;
extra = 40;
baselen = 103;
base = RandomInteger[10000, {baselen}];
repeat = 5;
signal = Flatten[Join[ConstantArray[base, repeat], Take[base, extra]]];
noisysignal = signal + RandomInteger[{-noise, noise}, Length[signal]];

我们计算FFT的绝对值。我们两端都是零。通过与邻居比较，对象将达到阈值。

sigfft = Join[{0.}, Abs[Fourier[noisysignal]], {0}];

现在我们创建两个0-1向量。在一个阈值中，通过为fft中的每个元素设置1，该元素大于其两个邻居的几何平均值的两倍。在另一方面，我们使用平均值（算术平均值），但我们将大小降低到3/4。这是基于一些实验。我们计算每种情况下1的数量。理想情况下，我们每个都会得到100，因为那就是“完美”无噪音且无尾部的非零数。

In[419]:= 
thresh1 = 
  Table[If[sigfft[[j]]^2 > 2*sigfft[[j - 1]]*sigfft[[j + 1]], 1, 
    0], {j, 2, Length[sigfft] - 1}];
count1 = Count[thresh1, 1]
thresh2 = 
  Table[If[sigfft[[j]] > 3/4*(sigfft[[j - 1]] + sigfft[[j + 1]]), 1, 
    0], {j, 2, Length[sigfft] - 1}];
count2 = Count[thresh2, 1]

Out[420]= 114

Out[422]= 100

现在我们对“重复”的价值进行最佳猜测，将总长度超过我们的平均值。

approxrepeats = Floor[2*Length[signal]/(count1 + count2)]
Out[423]= 5

所以我们发现基本信号重复5次。这可以开始精炼估计正确的长度（baselen，上面）。为此，我们可能会尝试删除末尾的元素，并查看我们何时让ffts更接近实际在非零值之间运行四个0。

可能用于估计重复次数的其他东西是在阈值化的fft的行程编码中找到模态的零数。虽然我实际上并没有尝试过这种方法，但是对于如何进行阈值处理（我的实验似乎有效）的详细信息中的错误选择看起来似乎很可靠。

Daniel Lichtblau

Answer 3

以下假设循环从第一个元素开始，并给出周期长度和周期。

findCyclingList[a_?VectorQ] :=
  Module[{repeats1, repeats2, cl, cLs, vec}, 
  repeats1 = Flatten@Differences[Position[a, First[a]]];
  repeats2 = Flatten[Position[repeats1, First[repeats1]]]; 
  If[Equal @@ Differences[repeats2] && Length[repeats2] > 2(* 
   is potentially cyclic - first element appears cyclically *),
   cl = Plus @@@ Partition[repeats1, First[Differences[repeats2]]];
   cLs = Partition[a, First[cl]];
   If[SameQ @@ cLs  (* candidate cycles all actually the same *), 
    vec = First[cLs];
    {Length[vec], vec}, $Failed], $Failed]  ]

测试

b = RandomInteger[50, {100}];
a = Join[b, b, b, b, Take[b, 27]];

findCyclingList[a]

{100, {47, 15, 42, 10, 14, 29, 12, 29, 11, 37, 6, 19, 14, 50, 4, 38, 
  23, 3, 41, 39, 41, 17, 32, 8, 18, 37, 5, 45, 38, 8, 39, 9, 26, 33, 
  40, 50, 0, 45, 1, 48, 32, 37, 15, 37, 49, 16, 27, 36, 11, 16, 4, 28,
   31, 46, 30, 24, 30, 3, 32, 31, 31, 0, 32, 35, 47, 44, 7, 21, 1, 22,
   43, 13, 44, 35, 29, 38, 31, 31, 17, 37, 49, 22, 15, 28, 21, 8, 31, 
  42, 26, 33, 1, 47, 26, 1, 37, 22, 40, 27, 27, 16}}

b1 = RandomInteger[10000, {100}]; 
a1 = Join[b1, b1, b1, b1, Take[b1, 23]];

findCyclingList[a1]

{100, {1281, 5325, 8435, 7505, 1355, 857, 2597, 8807, 1095, 4203, 
  3718, 3501, 7054, 4620, 6359, 1624, 6115, 8567, 4030, 5029, 6515, 
  5921, 4875, 2677, 6776, 2468, 7983, 4750, 7609, 9471, 1328, 7830, 
  2241, 4859, 9289, 6294, 7259, 4693, 7188, 2038, 3994, 1907, 2389, 
  6622, 4758, 3171, 1746, 2254, 556, 3010, 1814, 4782, 3849, 6695, 
  4316, 1548, 3824, 5094, 8161, 8423, 8765, 1134, 7442, 8218, 5429, 
  7255, 4131, 9474, 6016, 2438, 403, 6783, 4217, 7452, 2418, 9744, 
  6405, 8757, 9666, 4035, 7833, 2657, 7432, 3066, 9081, 9523, 3284, 
  3661, 1947, 3619, 2550, 4950, 1537, 2772, 5432, 6517, 6142, 9774, 
  1289, 6352}}

这种情况应该失败，因为它不是循环的。

findCyclingList[Join[b, Take[b, 11], b]]

$Failed

我尝试使用Repeated，例如a /. Repeated[t__, {2, 100}] -> {t}但它对我不起作用。

Answer 4

这对你有用吗？

period[a_] := 
   Quiet[Check[
      First[Cases[
         Table[
            {k, Equal @@ Partition[a, k]}, 
            {k, Floor[Length[a]/2]}], 
         {k_, True} :> k
         ]], 
      $Failed]]

严格来说，这会像

这样的事情失败

a = {1, 2, 3, 1, 2, 3, 1, 2, 3, 4, 5}

虽然这可以通过使用类似的东西来解决：

(Equal @@ Partition[a, k]) && (Equal @@ Partition[Reverse[a], k])

（可能只是提前计算Reverse[a]。）

Answer 5

我建议这样做。它借鉴了Verbeia和Brett的答案。

Do[
  If[MatchQ @@ Equal @@ Partition[#, i, i, 1, _], Return @@ i],
  {i, #[[ 2 ;; Floor[Length@#/2] ]] ~Position~ First@#}
] /. Null -> $Failed &

它在长时间内不如Vebeia的功能效率高，但在短时间内效率更快，而且也更简单。

Answer 6

我不知道如何在mathematica中解决它，但是下面的算法（用python编写）应该可行。它是O（n）所以速度应该没关系。

def period(array):
    if len(array) == 0:
        return False
    else:
        s = array[0]
        match = False
        end = 0
        i = 0

        for k in range(1,len(array)):
            c = array[k]

            if not match:
                if c == s:
                    i = 1
                    match = True
                    end = k
            else:
                if not c == array[i]:
                    match = False
                i += 1

        if match:
            return array[:end]
        else:
            return False

# False         
print(period([4, 5, 1, 2, 3, 4, 5, 1, 2, 3, 4, 5, 1, 2,1]))
# [4, 5, 1, 2, 3]            
print(period([4, 5, 1, 2, 3, 4, 5, 1, 2, 3, 4, 5, 1, 2]))
# False
print(period([4]))
# [4, 2]
print(period([4,2,4]))
# False
print(period([4,2,1]))
# False
print(period([]))

Answer 7

好的，只是为了在这里展示自己的作品：

ModifiedTortoiseHare[a_List] := Module[{counter, tortoise, hare},
Quiet[
 Check[
  counter = 1;
  tortoise = a[[counter]];
  hare = a[[2 counter]];
  While[(tortoise != hare) || (a[[counter ;; 2 counter - 1]] != a[[2 counter ;; 3 counter - 1]]),
   counter++;
   tortoise = a[[counter]];
   hare = a[[2 counter]];
  ];
 counter,
$Failed]]]

我不确定这是100％正确，特别是对于{pattern，pattern，different，pattern，pattern}这样的情况，当有很多重复元素时会变得越来越慢，如下所示：

{ 1,2,1,1, 1,2,1,1, 1,2,1,1, ...}

因为它进行了太多昂贵的比较。

Answer 8

#include <iostream>
#include <vector>
using namespace std;


int period(vector<int> v)
{
    int p=0; // period 0

    for(int i=p+1; i<v.size(); i++)
    {

        if(v[i] == v[0])
        {
            p=i; // new potential period


            bool periodical=true;
            for(int i=0; i<v.size()-p; i++)
            {
                if(v[i]!=v[i+p])
                {
                    periodical=false;
                    break;
                }
            }
            if(periodical) return p;


            i=p; // try to find new period
        }
    }

    return 0; // no period

}


int main()
{

    vector<int> v3{1,2,3,1,2,3,1,2,3};
    cout<<"Period is :\t"<<period(v3)<<endl;


    vector<int> v0{1,2,3,1,2,3,1,9,6};
    cout<<"Period is :\t"<<period(v0)<<endl;

    vector<int> v1{1,2,1,1,7,1,2,1,1,7,1,2,1,1};
    cout<<"Period is :\t"<<period(v1)<<endl;
    return 0;
}

Answer 9

这听起来可能与sequence alignment有关。这些算法已经过充分研究，可能已在mathematica中实现。

在Mathematica中找到（重复）列表的周期的最佳方法是什么？

9 个答案: