Question

我在perl上有以下字符串：

my $string = xyz;1;xyz;2;a;2;b;2

我想为此字符串构建一个哈希，如下所示：

my @array =split /;/,$string;

$hash{xyz} =(1,2);
$hash{b}=(2);
$hahs{a}=(2);

这样做的perl方式是什么？

Answer 1

my $string = "xyz;1;xyz;2;a;2;b;2";
my %hash;
push @{$hash{$1}}, $2 while $string =~ s/^(\w+);(\d+);?//g;

实际上

push @{$hash{$1}}, $2 while $string =~ m/(\w+);(\d+);?/g;

会更好，因为它不会占用原来的字符串。

Answer 2

假设您希望同一个键的多个值成为数组引用，那么一种方法就是这样：

my @values = split /;/, $string;

my %hash;
while( @values ) { 
    my $key = shift @values;
    my $val = shift @values;

    if ( exists $hash{$key} && !ref $hash{$key} ) { 
        # upgrade to arrayref
        $hash{$key} = [ $hash{$key}, $val ];
    } elsif ( ref $hash{$key} ) { 
        push @{ $hash{$key} }, $val;
    } else { 
        $hash{$key} = $val;
    }
}

使用您的数据，这将产生类似

的结构

    {
      'a' => '2',
      'b' => '2',
      'xyz' => [
                 '1',
                 '2'
               ]
    };

Answer 3

Drats：你有重复的键......我想用map或grep做点什么。

这很容易理解：

my $string = "xyz;1;xyz;2;a;2;b;2";
my @array = split /;/ => $string;

my %hash;
while (@array) {
    my ($key, $value) = splice @array, 0, 2;
    $hash{$key} = [] if not exists $hash{$key};
    push @{$hash{$key}}, $value;
}

即使密钥不在您的字符串中，该程序也能正常工作。例如，即使xyz被其他值对分隔，以下内容仍然有效：

my $string = "xyz;1;a;2;b;2;xyz;2";

我假设$hash{b}=(2);表示您希望$hash{b}的值是对单个成员数组的引用。这是对的吗？

Answer 4

执行此操作的最简单（标准）方法可能是List::MoreUtils::natatime

use List::MoreUtils qw<natatime>;
my $iter = natatime 2 => split /;/, 'xyz;1;xyz;2;a;2;b;2';
my %hash;
while ( my ( $k, $v ) = $iter->()) { 
    push @{ $hash{ $k } }, $v;
}

然而，抽出我可能想再做的部分......

use List::MoreUtils qw<natatime>;

sub pairs { 
    my $iter = natatime 2 => @_;
    my @pairs;
    while ( my ( $k, $v ) = $iter->()) { 
        push @pairs, [ $k, $v ];
    }
    return @pairs;
}

sub multi_hash {
    my %h;
    push @{ $h{ $_->[0] } }, $_->[1] foreach &pairs;
    return wantarray ? %h : \%h;
}

my %hash = multi_hash( split /;/, 'xyz;1;xyz;2;a;2;b;2' );

从字符串构建哈希

4 个答案: