Question

我有类似

的哈希

 $hash{$kayA}{$keyB}{val=>$value};

我需要把它放到一个html表中，包含$ keyA的TD需要基于$ keyB键的数量的行数

所以输出可能看起来像

<html>
<body>
<table border='1'>
  <tr><th colspan='2' >Col A</th><th>Col B</th><th>Value</th></tr>
  <tr>
  <td rowspan='2'><input name='myButton' type= "radio" id ="R1"></td>
  <td rowspan='2'> this is first kay</td>
  <td> this is second key 1</td><td>Value 1</td>
  </tr>
  <tr>
  <td>this is second key 2</td><td>Value 2</td>
  </tr>
</table>
</body>
</html>

就我的perl脚本而言，我正在努力将tr放到正确的位置

#!/usr/bin/perl

$hash{$kayA}{$keyB}{val=>$value};
my $TabPrt = "<table><tr><th>Col A></th><th>Col B</th><th>Value</th></tr>";
for my $keyA (sort keys %hash)
  {
   my $Row = scaler keys %{$hash}{kayA};
   $Row = "rowspan='$Row'";

   $TabPrt = $TabPrt. "<tr>  <td><input name='myButton' type= "radio" id ="R1"></td><td $Row></td>";
   for my $keyB (sort keys %{$hash}{$keyA}
    {
      my $val = hash{$kayA}{$keyB}{val};
      $TabPrt = $TabPrt . " <td>$keyB</td><td>$val</td>"
    }
  }

 $TabPrt = $TabPrt . "</tr></table>";

Answer 1

我不太了解您的数据结构和代码。

这个$hash{$kayA}{$keyB}{val=>$value};编译，但在Perl中没有实际意义。

此外，这条线路有问题：

$TabPrt = $TabPrt. "<tr>  <td><input name='myButton' type= "radio" id ="R1"></td><td $Row></td>";

它不会编译，因为字符串"<tr> <td><input name='myButton' type= "在radio之前终止。我想你的意思是

$TabPrt .= q(<tr><td><input name="myButton" type="radio" id ="R1"></td><td>$Row</td>);

使用q()或qq()（插值）引号运算符引用包含'或"个字符的字符串。

我假设您希望表格呈现为

+----------------------------------+------------------------+---------+
| Col A                            | Col B                  | Value   |
+==========+=======================+========================+=========+
| o Button | this is the first key | this is the second key | Value 1 |
|          |                       +------------------------+---------+
|          |                       | this is the second key | Value 2 |
+----------+-----------------------+------------------------+---------+

现在让我们假设您的哈希看起来像

my %hash = (
    key1 => { A => "val1", B => "val2" },
    key2 => { C => "val1", D => "val2" },
);

然后我们可以迭代这个哈希并构造HTML：

sub make_table_corpus {
    my ($hash) = @_;
    my $html = "";
    for my $key (sort keys %$hash) {
        my $sub_hash = $hash->{$key};
        # first: how many rows will this key span?
        my $rowspan = keys %$sub_hash;
        # then: prepare all the secondary keys. Will return HTML fragments:
        my @secondary = prep_secondary_keys($sub_hash);
        $html .= html("tr", {},
            html("td", {rowspan => $rowspan}, " o Button "),
            html("td", {rowspan => $rowspan}, $key),
            # put the first secondary key here
            shift @secondary,
        );
        # append the other secondary keys:
        $html .= html("tr", {}, $_) for @secondary;
    }
    return $html;
}

# emits html fragments of key-value pairs, as <td> cells.
sub prep_secondary_keys {
    my ($hash) = @_;
    map { html("td", {}, $_) . html("td", {}, $hash->{$_}) }
        sort keys %$hash;
}

# creates a html fragment
sub html {
    my ($name, $attr, @childs) = @_;
    my $attrstring = "";
    while (my ($attname, $value) = each %$attr) {
        $value =~ s/"/&quot;/g;
        $attrstring .= qq( $attname="$value");
    }
    return join "", qq(<$name$attrstring>), @childs, qq(</$name>);
}

然后：

print make_table_corpus(\%hash);

使用上面的哈希，这将产生类似

的输出

<tr>
  <td rowspan="2"> o Button </td>
  <td rowspan="2">key1</td>
  <td>A</td>
  <td>val1</td>
</tr>
<tr>
  <td>B</td>
  <td>val2</td>
</tr>
<tr>
  <td rowspan="2"> o Button </td>
  <td rowspan="2">key2</td>
  <td>C</td>
  <td>val1</td>
</tr>
<tr>
  <td>D</td>
  <td>val2</td>
</tr>

（当然没有意图）

我做了什么不同

我没有做语法错误（use strict; use warnings以警告错误和错误）
辅助密钥由外部子程序处理。这样，我们可以简单地获取第一个HTML片段并轻松地将其放入第一行。
我写了html子，以避免源代码中出现过多的引用问题。虽然这不能取代模板系统，但它会让生活变得更轻松，并为错误引入单点故障，这使得问题更容易解决。

扩展解决方案以打印出表头，并生成有效的HTML表格是一件非常简单的步骤。

使用colspan从perl Hash构建表

1 个答案:

我做了什么不同