Question

我的xml文档包含人员列表，这些人可以拥有0个或更多个昵称。我无法在xslt文档中正确显示所有昵称。

我可以使用以下列出所有昵称：

<xsl:for-each select="name/nickname">

    Nickname: <xsl:value-of select="." />

</xsl:for-each>

这的输出类似于：

Nickname: nickname1
Nickname: nickname2

这是一个问题，因为我想获得没有昵称的输出：被列出这么多次，即

Nickname: nickname1, nickname2.

我目前拥有的是：

<p>
    Nickname: 

    <xsl:for-each select="name/nickname">

        <xsl:value-of select="." />, 

    </xsl:for-each>
</p>

问题是：

即使昵称不存在，昵称也将至少打印一次。
总是会留下逗号（，）。

我希望有解决这两个问题的建议，我试图使用！=“”但我不确定如果一个人不包含昵称，是否允许这样做。

谢谢：）

Answer 1

此转化：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="name[nickname]">
     <xsl:text>&#xA;Nicknames: </xsl:text>
       <xsl:apply-templates select="nickname"/>
 </xsl:template>

 <xsl:template match="nickname">
  <xsl:if test="not(position() = 1)">
    <xsl:text>, </xsl:text>
  </xsl:if>
  <xsl:apply-templates/>
 </xsl:template>
</xsl:stylesheet>

应用于此XML文档时：

<t>
 <person>
  <name trueName="John">
    <nickname>X1</nickname>
    <nickname>X2</nickname>
    <nickname>X3</nickname>
  </name>
 </person>
 <person>
  <name trueName="Peter">
    <nickname>Y1</nickname>
    <nickname>Y2</nickname>
    <nickname>Y3</nickname>
  </name>
 </person>
 </t>

生成想要的正确结果：

Nicknames: X1, X2, X3
Nicknames: Y1, Y2, Y3

Answer 2

类似的东西（未经测试）：

<xsl:when test="name/nickname">
 Nickname:
 <xsl:for-each select="name/nickname">
   <xsl:value-of select="." />
   <xsl:if test="count(following-sibling::nickname)">,</xsl:if> 
  </xsl:for-each>
</xsl:when>

Answer 3

输入：

<?xml version="1.0" encoding="UTF-8"?>
<test>
  <nickname>1</nickname>
  <nickname>2</nickname>
  <nickname>3</nickname>
</test>

转换：

<xsl:template match='/'>
    <xsl:if test='count(//nickname) > 0'>
      <result>
      <xsl:for-each select='//nickname'>
        <xsl:choose>
          <xsl:when test='position() = 1'>
            Nickname : <xsl:value-of select="."/><xsl:if test="not(position() = last())">,</xsl:if>
          </xsl:when>
          <xsl:otherwise>
            <xsl:value-of select="."/>
            <xsl:if test="not(position() = last())">,</xsl:if>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:for-each>
      </result>
    </xsl:if>
  </xsl:template>

输出：

<?xml version="1.0" encoding="UTF-8"?>
<result>Nickname : 1,2,3</result>

Answer 4

或者，

<xsl:for-each select="name/nickname">
    <xsl:if test="position() = 1">Nickname: </xsl:if>
    <xsl:value-of select="." />
    <xsl:if test="not(position()=last())">, </xsl:if>
</xsl:for-each>

Answer 5

或者在XSLT 2.0中：

输入：

<?xml version="1.0" encoding="UTF-8"?>
<test>
  <nickname>1</nickname>
  <nickname>2</nickname>
  <nickname>3</nickname>
</test>

转换：

<xsl:template match='/'>
Nickname: <xsl:value-of select="/test/nickname" separator=", "/>
</xsl:template>

格式化XSLT文档以在一行上显示多个昵称

5 个答案: