Question

我正在寻找一种在Prolog中构建表达式树的方法。我已经做了一些实验，并提出了以下工作代码（只处理常量和加号表达式）：

const(_).
plus(_, _).

eval(const(R), R).

eval(plus(A, B), R) :- number(A), number(B), R is A+B.
eval(plus(A, B), R) :- number(A), eval(B, B_R), R is A+B_R.
eval(plus(A, B), R) :- eval(A, A_R), number(B), R is A_R+B.
eval(plus(A, B), R) :- eval(A, A_R), eval(B, B_R), R is A_R+B_R.

这种方法有没有更简单的替代方案？我是否必须为我计划添加到程序中的每个操作符定义这4个案例？

Answer 1

在这里看到另一个模式，利用DCG和（一种）懒惰的评估：

/*
File:    dcg_calculator.pl
Author:  Carlo,,,
Created: Aug 16 2011
Purpose: associativity and precedences in calculator
*/

:- module(dcg_calculator, [dcg_calculator/2, expr//1]).
%- [library(http/dcg_basics)]. obsolete
:- [library(dcg/basics)].

/* usage

?- dcg_calculator("1+(-2-2)",S),V is S.
S = 1+ (-2-2),
V = -3 ;
false.

*/
dcg_calculator(Formula, IsEvaluable) :-
    phrase(expr(IsEvaluable), Formula, []).

expr(Evaluable) -->
    sum(Evaluable).

sum(S) -->
    product(P), sum_1(P, S).
sum_1(L, S) -->
    "+", product(P), sum_1(L + P, S);
    "-", product(P), sum_1(L - P, S);
    {L = S}.

product(P) -->
    value(V), product_1(V, P).
product_1(V, P) -->
    "*", value(U), product_1(V * U, P);
    "/", value(U), product_1(V / U, P);
    {V = P}.

% value(V) -->
%   {var(V)} -> {V=0 /* between(0, 9, V)*/ }, "0".

value(V) -->
    "(", expr(V), ")" ;
    number(V).

使用语法对数据结构进行建模，这是Prolog中非常有用的技术。语法使用它是PEG的实现。来自SWI-Prolog的依赖性非常有限，只是数字// 1。

Answer 2

我认为应该这样做，虽然我不熟悉构造pred1(pred2(...)...) :- ...（我的Prolog非常生疏）。

eval(A, A) :- number(A).
eval(plus(A, B), R) :- eval(A, A_R), eval(B, B_R), R is A_R+B_R.

在Prolog中构建表达式树

2 个答案: