Question

如何获取最大（最小）元素（res.val和res.pos）的值以及位置？

thrust::host_vector<float> h_vec(100);
thrust::generate(h_vec.begin(), h_vec.end(), rand);
thrust::device_vector<float> d_vec = h_vec;

T res = -1;
res = thrust::reduce(d_vec.begin(), d_vec.end(), res, thrust::maximum<T>());

Answer 1

请勿使用thrust::reduce。在thrust::max_element中使用thrust::min_element（thrust/extrema.h）：

thrust::host_vector<float> h_vec(100);
thrust::generate(h_vec.begin(), h_vec.end(), rand);
thrust::device_vector<float> d_vec = h_vec;

thrust::device_vector<float>::iterator iter =
  thrust::max_element(d_vec.begin(), d_vec.end());

unsigned int position = iter - d_vec.begin();
float max_val = *iter;

std::cout << "The maximum value is " << max_val << " at position " << position << std::endl;

将空范围传递给max_element时要小心 - 您将无法安全地取消引用结果。

Answer 2

Jared Hoberock已经圆满地回答了这个问题。我希望在下面稍微更改一下，以便在cudaMalloc而不是device_vector容器分配数组时常见情况。

我们的想法是围绕device_pointer原始指针包裹dev_ptr cudaMalloc，投出min_element的输出（我考虑的是device_pointer min_ptr的最小值而不是最大值而不失一般性，然后将min_ptr[0]的最小值和&min_ptr[0] - &dev_ptr[0]的位置找到。

#include "cuda_runtime.h"
#include "device_launch_paraMeters.h"

#include <thrust\device_vector.h>
#include <thrust/extrema.h>

/***********************/
/* CUDA ERROR CHECKING */
/***********************/
#define gpuErrchk(ans) { gpuAssert((ans), __FILE__, __LINE__); }
inline void gpuAssert(cudaError_t code, const char *file, int line, bool abort=true)
{
   if (code != cudaSuccess) 
   {
      fprintf(stderr,"GPUassert: %s %s %d\n", cudaGetErrorString(code), file, line);
      if (abort) exit(code);
   }
}

/********/
/* MAIN */
/********/
int main() {

    srand(time(NULL));

    const int N = 10;

    float *h_vec = (float *)malloc(N * sizeof(float));
    for (int i=0; i<N; i++) {
        h_vec[i] = rand() / (float)(RAND_MAX);
        printf("h_vec[%i] = %f\n", i, h_vec[i]);
    }

    float *d_vec; gpuErrchk(cudaMalloc((void**)&d_vec, N * sizeof(float)));
    gpuErrchk(cudaMemcpy(d_vec, h_vec, N * sizeof(float), cudaMemcpyHostToDevice));

    thrust::device_ptr<float> dev_ptr = thrust::device_pointer_cast(d_vec);

    thrust::device_ptr<float> min_ptr = thrust::min_element(dev_ptr, dev_ptr + N);

    float min_value = min_ptr[0];
    printf("\nMininum value = %f\n", min_value);
    printf("Position = %i\n", &min_ptr[0] - &dev_ptr[0]);

}

使用CUDA Thrust查找最大元素值及其位置

2 个答案: