Question

我正在学习Scheme，我已经阅读了基础知识，但我仍然无法想象如何将Java类“映射”到Scheme代码。你们中的任何人能帮助我吗？我只需要有人向我展示如何在Scheme中查看最终细节并让我的想法得到解决：

public class sumFibonacciValues {
    public static void main(String [] args) {
        int n = 4000000;
        long i2 = 1, i1 = 1, Fibo = 0, temp = 1;
        while(i2 < n) {
            temp = i1 + i2;
            i1 = i2;
            i2 = temp;
            if(i2 % 2 == 0)
                Fibo += i2;
        }
        System.out.println(Fibo);
    }
}

Answer 1

我不会回答那些看起来像家庭作业的东西，但是“惯用”的评论只是要求证明它真的不是那么远。首先，直接翻译：

(define (sum-fibonacci-values)
  (define n 4000000)
  (define i2 1)
  (define i1 1)
  (define fibo 0)
  (define temp 1)
  (let loop ()
    (when (< i2 n)
      (set! temp (+ i1 i2))
      (set! i1 i2)
      (set! i2 temp)
      (when (zero? (modulo i2 2)) (set! fibo (+ fibo i2)))
      (loop)))
  (write fibo))

其次，通过删除冗余突变使其成为“惯用”，而只是绑定新值，并使用尾递归循环。请注意，此代码仍与原始代码直接相关：

(define (sum-fibonacci-values)
  (define n 4000000)
  (let loop ([i2 1] [i1 1] [fibo 0] [temp 1])
    (if (< i2 n)
      (let* ([temp (+ i1 i2)]
             [i1 i2]
             [i2 temp]
             [fibo (if (zero? (modulo i2 2)) (+ fibo i2) fibo)])
        (loop i2 i1 fibo temp))
      fibo)))

最后，既然代码更清晰，你可以看到有一些冗余。这是一个清理版本：

(define (sum-fibonacci-values)
  (define n 4000000)
  (let loop ([i2 1] [i1 1] [fibo 0])
    (if (< i2 n)
      (let ([i3 (+ i1 i2)])
        (loop i3 i2 (if (zero? (modulo i3 2)) (+ fibo i3) fibo)))
      fibo)))

请注意，可以对Java代码执行相同的清理。（但这真的留给了读者......）

帮我把这个Java翻译成Scheme来让事情顺利进行

1 个答案: