Question

这是一个任意的例子。这是一个真正的问题，但我不能分享真正的代码。

我有一个没有标准化节点名称的xml字符串。例如：

<row>
  <date name="date1" id="101"></date>
  <element1 name="ele1" id="111">
    <stuff></stuff>
    <stuff></stuff>
    <stuff></stuff>
  </element1>
  <element2 name="ele2" id="121">
  </element2>
  ...
  <element15 name="ele15" id="1151></element15>
</row>

一些元素节点有东西，有些则没有。

此xml包含在数据库表中（出于参数考虑：table1，column1）。

我需要使用pl / sql循环遍历此代码以获取： 1.日期字段的name属性 2.日期字段的id属性 3.日期之后第一个节点的name属性 4.日期之后第一个节点的id属性 5.日期之后第二个节点的name属性 6.日期

之后的第二个节点的id属性

我需要为前4行（任意）行执行此操作（sql查询具有rownum＆lt; 5）

到目前为止，我一直在尝试使用

获取数据

set serveroutput on format word_wrapped;
DECLARE

    x_att_name varchar2(4000);
    x_id varchar2(4000);
    x_oth_name varchar2(4000);
    x_oth_id varchar2(4000);
    aCount number := 1;
    xpath1 varchar2(4000);
    xpath2 varchar2(4000);

BEGIN

    FOR i IN  (
                  SELECT 

                  EXTRACT(column1, '/row/date/@name') as att_name,
                  EXTRACT(column1, '/row/date/@id') as id,
                  EXTRACT(column1, '/row/date/following::*/@name') as other_name,
                  EXTRACT(column1, '/row/date/following::*/@id') as other_id

                  FROM table1
                  WHERE column1is not null and rownum < 5
              )
    LOOP

            x_att_name := i.att_name.getStringVal();
            x_id := i.id.getStringVal();
            x_oth_name := i.other_name.getStringVal();
            x_oth_id := i.other_id.getStringVal();

            dbms_output.put_line('LOOPS: ' || aCount);
            dbms_output.put_line(' DATE: ' || x_att_name);
            dbms_output.put_line(' PKDATE: ' || x_id);
            dbms_output.put_line(' FLDNAME: ' || x_oth_name);
            dbms_output.put_line(' PKFLD: ' || x_oth_id);

            aCount := aCount+1;

    END LOOP;

END;

当我跑步时，我得到：

anonymous block completed
LOOPS: 1
 DATE: date1
 PKDATE: 101
 FLDNAME: ele1ele2ele3ele4...ele15
 PKFLD: 111121131141...1151
....

所以它基本上将所有名称属性从该数据库记录中的其余节点中捣碎回来（而不是像我希望的那样在列表中）。

对于id来说也是如此。

注意事项： - 所有元素节点都具有广泛变化的名称属性。它们不仅仅是三个字符串的列表，其末尾添加了数字（ele1）; - 每个节点的所有id属性都有很大的不同。它们是混乱的数字串（例如10212），不按asc / dsc顺序，不是连续的，并且不与任何模式相关。

显然，我不能只循环遍历所有元素节点，因为它们都是唯一的。我无法弄清楚如何编写一个xpath来获取“在此之后的所有节点”。

我是pl / sql的新手，并且在几天内学会了你在这里看到的所有东西，所以显然语言中更复杂/更微妙的点仍然无法实现。

非常感谢您提供的任何帮助。如果我有任何拼写错误或以任何方式不清楚，请告诉我，以便澄清。

由于 Q

Answer 1

您正在寻找XMLTABLE。

create table so10t(
  id number,
  data xmltype
);

insert into so10t values (1, xmltype(
'<row>
  <date name="date1" id="101"></date>
  <element1 name="ele1" id="111">
    <stuff></stuff>
    <stuff></stuff>
    <stuff></stuff>
  </element1>
  <element2 name="ele2" id="121">
  </element2>
  <element15 name="ele15" id="1151"></element15>
</row>'));
insert into so10t values (2, xmltype(
'<row>
  <date name="date2" id ="102"/>
  <elem23 name="ele23" id="201">
    <whatever/>
  </elem23>
  <elem56 name="ele56" id="402"/>
  <elem112 name="ele112" id="804"/>
</row>'));

declare
  type rec_t is record(
    date_name varchar2(10),
    date_id number,
    first_elem_name varchar2(10),
    first_elem_id number,
    second_elem_name varchar2(10),
    second_elem_id number
  );
  rec rec_t;
  cur sys_refcursor;
begin
  open cur for
    select x.*
      from so10t,
      xmltable('row' passing so10t.data
               columns
               /* 1. the name attribute of the date field */
               date_name varchar2(10) path 'date/@name',
               /* 2. the id attribute of the date field */
               date_id number path 'date/@id',
               /* 3. the name attribute of the first node after the date */
               first_elem_name varchar2(10) path 'date/(following::*)[1]/@name',
               /* 4. the id attribute of the first node after the date */
               first_elem_id number path 'date/(following::*)[1]/@id',
               /* 5. the name attribute of the second node after the date */
               second_elem_name varchar2(10) path 'date/(following::*)[1]/(following::*)[1]/@name',
               /* 6. the id attribute of the second node after the date */
               second_elem_id number path 'date/(following::*)[1]/(following::*)[1]/@id'
               ) x 
      where rownum < 5 ;

  fetch cur into rec;
  while cur%found loop
    dbms_output.put_line(rec.date_name || ';' || rec.date_id || ';' ||
                         rec.first_elem_name || ';' || rec.first_elem_id || ';' ||
                         rec.second_elem_name || ';' || rec.second_elem_id);
    fetch cur into rec;
  end loop;

  close cur;
end;
/

PL / SQL：如何遍历sql extract（）结果

1 个答案: