Question

所以我有一个字符串

test = 'a,b,c,d';

我想将此字符串拆分为由逗号分隔的每个单词。然后我想循环结果。

我见过这个解决方案：

WITH t AS
( SELECT 'a,b,c,d,e' AS txt FROM dual
)
SELECT CAST(REGEXP_SUBSTR (txt, '[^,]+', 1, level) AS CHAR(12))
FROM t
CONNECT BY level <= LENGTH(regexp_replace(txt,'[^,]*'))+1;

但是，它不允许我循环结果集。我需要对每个子字符串进行额外的处理。

如何循环使用此结果集？

Answer 1

您可以在查询中使用内联视图：

WITH t AS (
  SELECT 'a,b,c,d,e' AS txt FROM dual
)
SELECT extra_processing( value )
FROM   (
  SELECT CAST(REGEXP_SUBSTR (txt, '[^,]+', 1, level) AS CHAR(12)) AS value
  FROM t
  CONNECT BY level <= LENGTH(regexp_replace(txt,'[^,]*'))+1
);

由于这是用PL / SQL标记的 - 为什么要使用SQL：

Oracle安装程序：

用于在分隔符上拆分字符串的小辅助函数：

CREATE OR REPLACE FUNCTION split_String(
  i_str    IN  VARCHAR2,
  i_delim  IN  VARCHAR2 DEFAULT ','
) RETURN SYS.ODCIVARCHAR2LIST DETERMINISTIC
AS
  p_result       SYS.ODCIVARCHAR2LIST := SYS.ODCIVARCHAR2LIST();
  p_start        NUMBER(5) := 1;
  p_end          NUMBER(5);
  c_len CONSTANT NUMBER(5) := LENGTH( i_str );
  c_ld  CONSTANT NUMBER(5) := LENGTH( i_delim );
BEGIN
  IF c_len > 0 THEN
    p_end := INSTR( i_str, i_delim, p_start );
    WHILE p_end > 0 LOOP
      p_result.EXTEND;
      p_result( p_result.COUNT ) := SUBSTR( i_str, p_start, p_end - p_start );
      p_start := p_end + c_ld;
      p_end := INSTR( i_str, i_delim, p_start );
    END LOOP;
    IF p_start <= c_len + 1 THEN
      p_result.EXTEND;
      p_result( p_result.COUNT ) := SUBSTR( i_str, p_start, c_len - p_start + 1 );
    END IF;
  END IF;
  RETURN p_result;
END;
/

<强>代码：

DECLARE
  list SYS.ODCIVARCHAR2LIST := split_String( 'a,b,c,d,e' );
BEGIN
  FOR i IN 1 .. list.LAST LOOP
    -- do your extra processing
  END LOOP;
END;
/

或者您可以在SQL中执行此操作：

SELECT extra_processing( COLUMN_VALUE )
FROM   TABLE( split_String( 'a,b,c,d,e' ) )

（注意：COLUMN_VALUE是Oracle为TABLE运算符生成的值提供的列名。）

PL SQL - 如何循环拆分csv字符串的结果？

1 个答案: