Question

我想在我的词法分析器中解析这样的东西：

( begin expression )

其中表达式也被括号括起来。表达式中的内容并不重要，我只想将(begin和匹配的)之间的所有内容作为标记。一个例子是：

(begin 
    (define x (+ 1 2)))

所以令牌的文字应为

(define x (+ 1 2)))

类似

PROGRAM : LPAREN BEGIN .* RPAREN;

（显然）不起作用，因为只要他看到“）”，他就认为规则已经结束，但我需要匹配括号。

我该怎么做？

Answer 1

在lexer规则中，您可以递归调用规则。所以，这是解决这个问题的一种方法。另一种方法是跟踪开括号和闭括号的数量，只要你的计数器大于零，就让gated semantic predicate 循环。

演示：

T.G

grammar T;

parse
  :  BeginToken {System.out.println("parsed :: " + $BeginToken.text);} EOF
  ;

BeginToken 
@init{int open = 1;}
  :  '(' 'begin' ( {open > 0}?=>              // keep reapeating `( ... )*` as long as open > 0
                     ( ~('(' | ')')           // match anything other than parenthesis
                     | '('          {open++;} // match a '(' in increase the var `open`
                     | ')'          {open--;} // match a ')' in decrease the var `open`
                     )
                 )*
  ;

Main.java

import org.antlr.runtime.*;

public class Main {
  public static void main(String[] args) throws Exception {
    String input = "(begin (define x (+ (- 1 3) 2)))";
    TLexer lexer = new TLexer(new ANTLRStringStream(input));
    TParser parser = new TParser(new CommonTokenStream(lexer));
    parser.parse();
  }
}

java -cp antlr-3.3-complete.jar org.antlr.Tool T.g
javac -cp antlr-3.3-complete.jar *.java
java -cp .:antlr-3.3-complete.jar Main

parsed :: (begin (define x (+ (- 1 3) 2)))

请注意，您需要注意源内可能包含括号的字符串文字：

BeginToken
@init{int open = 1;}
  :  '(' 'begin' ( {open > 0}?=>              // ...
                     ( ~('(' | ')' | '"')     // ...
                     | '('          {open++;} // ...
                     | ')'          {open--;} // ...
                     |  '"' ...               // TODO: define a string literal here
                     )
                 )*
  ;

或可能包含括号的注释。

谓词的建议使用了一些特定于语言的代码（在本例中为Java）。递归调用词法分析器规则的一个优点是你的词法分析器中没有自定义代码：

BeginToken 
  :  '(' Spaces? 'begin' Spaces? NestedParens Spaces? ')'
  ;

fragment NestedParens
  :  '(' ( ~('(' | ')') | NestedParens )* ')'
  ;

fragment Spaces
  :  (' ' | '\t')+
  ;

ANTLR：如何用词法分析器解析匹配括号内的区域

1 个答案:

演示：

T.G

Main.java