Question

nsi脚本中的代码段：

VIProductVersion 1.2.0.0   
VIAddVersionKey /LANG=${LANG_ENGLISH} FileVersion 1.1.0.0

我想将 FileVersion 设置为1.1.0.0，但在文件属性中，它设置为1.2.0.0。我还注意到VIProductVersion自己执行了 FileVersion 键并设置了它的值。

文档说明VIProductVersion添加了产品版本，但我看到的是实际添加了 FileVersion 。这是NSIS中的错误吗？ VIAddVersionKey FileVersion如果设置的值被VIProductVersion设置为覆盖，则其目的是什么？

VIAddVersionKey需要VIProductVersion调用，否则脚本不会编译。

我正在使用的版本：EclipseNSIS 0.9.8; MakeNSIS 2.46。操作系统：Windows 7。

Answer 1

版本信息资源分为两部分：

VS_FIXEDFILEINFO是包含产品和文件版本的固定块，VIProductVersion设置此
零个，一个或多个（多种语言）带有一个或多个name = value字符串的字符串块，VIAddVersionKey设置这些字符串。

如果字符串不存在，某些应用程序使用FileVersion字符串并回退到VS_FIXEDFILEINFO :: dwFileVersion，其他应用程序仅使用VS_FIXEDFILEINFO :: dwFileVersion等。

VIProductVersion "1.2.3.4"将生成一个类似于

的版本标头

1 VERSIONINFO
FILEVERSION 1,2,3,4
PRODUCTVERSION 1,2,3,4
FILEOS 0x4
FILETYPE 0x1

这通常已经足够，但它不会让你设置PRODUCTVERSION！= FILEVERSION。

我认为这是NSIS中的一个错误，他们应该添加一个VIFileVersion命令或将VIProductVersion扩展到VIProductVersion <productver> [filever]。

您可以在tracker上添加功能请求。

~~与此同时，您可以通过使用！packhdr~~

在构建期间调用resource hacker来解决此问题。

编辑：

可以在2.46编译时用！packhdr，外部第三方工具（我无法让reshacker导入.rc版本资源，因此我必须首先转换为.res）和可怕的黑客攻击：

!macro HackyVIFileVersion reshack gorcjorg fixedfilever
;http://www.angusj.com/resourcehacker/
;http://web.archive.org/web/20090918063311/http://www.jorgon.freeserve.co.uk/Gorcjorg.zip
!searchreplace HackyVIFileVersion_id "${__TIME__}" ":" ""
!define HackyVIFileVersion_cmd "$%TEMP%\nsisVIFV${HackyVIFileVersion_id}.cmd"
!appendfile "${HackyVIFileVersion_cmd}" `@echo off&setlocal ENABLEEXTENSIONS DISABLEDELAYEDEXPANSION$\n`
!appendfile "${HackyVIFileVersion_cmd}" `set eh=%TEMP%\exehead%~1.tmp$\n`
!appendfile "${HackyVIFileVersion_cmd}" `set rh=%~2$\n`
!appendfile "${HackyVIFileVersion_cmd}" `call "%rh%" -extract "%eh%", "%eh%1.rc", VersionInfo,1,$\n`
!appendfile "${HackyVIFileVersion_cmd}" `> "%eh%2.rc" echo.LANGUAGE LANG_ENGLISH, SUBLANG_ENGLISH_US $\n` ;must force lang for Gorcjorg
!appendfile "${HackyVIFileVersion_cmd}" `FOR /F "usebackq tokens=* delims=" %%A IN ("%eh%1.rc") DO ($\n`
!appendfile "${HackyVIFileVersion_cmd}" `   FOR /F "usebackq" %%B IN ('%%A') DO ($\n`
!appendfile "${HackyVIFileVersion_cmd}" `       if "%%~B"=="FILEVERSION" (>> "%eh%2.rc" echo.FILEVERSION %~4) else (>> "%eh%2.rc" echo.%%A)$\n`
!appendfile "${HackyVIFileVersion_cmd}" `   )$\n`
!appendfile "${HackyVIFileVersion_cmd}" `)$\n`
!appendfile "${HackyVIFileVersion_cmd}" `call "%~3" /fo "%eh%.res" /r "%eh%2.rc"$\n`
!appendfile "${HackyVIFileVersion_cmd}" `call "%rh%" -addoverwrite "%eh%", "%eh%", "%eh%.res", versioninfo,1,$\n`
!appendfile "${HackyVIFileVersion_cmd}" `del "%eh%2.rc"&del "%eh%1.rc"&del "%eh%.res"&del "%~0"`
!packhdr "$%TEMP%\exehead${HackyVIFileVersion_id}.tmp" '"${HackyVIFileVersion_cmd}" "${HackyVIFileVersion_id}" "${reshack}" "${gorcjorg}" "${fixedfilever}"'
!undef HackyVIFileVersion_cmd
!undef HackyVIFileVersion_id 
!macroend


VIProductVersion "1.2.3.4"
VIAddVersionKey /LANG=1033 FileVersion 5.6.7.8
VIAddVersionKey /LANG=1033 ProductVersion "1.2.3.4"
VIAddVersionKey /LANG=1033 Comments "A test comment"
!insertmacro HackyVIFileVersion "C:\tools\ResHacker.exe" "C:\tools\GoRC.exe" "5,6,7,8"

...你最终获得了这个版本资源：

1 VERSIONINFO
FILEVERSION 5,6,7,8
PRODUCTVERSION 1,2,3,4
FILEOS 0x4
FILETYPE 0x1
{
BLOCK "StringFileInfo"
{
    BLOCK "040904e4"
    {
        VALUE "Comments", "A test comment"
        VALUE "FileVersion", "5.6.7.8"
        VALUE "ProductVersion", "1.2.3.4"
    }
}

BLOCK "VarFileInfo"
{
    VALUE "Translation", 0x0409 0x04E4
}
}

为什么VIProductVersion参数会覆盖ProductVersion键的值？

1 个答案: