使用条形图/条形图绘制分类变量

Question

data

我正在尝试为 sept 和 oct 波绘制条形图。如图所示，您可以看到 id 是跨时间调查的个人。所以在一张图中，我需要绘制 sept in-house、oct in-house、sept out-house、oct out-house 并且只需要显示在 sept in-house、oct in-house 中说是的人的比例，九月外屋，八月外屋。并非所有类别都必须考虑在内。

此外，我必须显示每个类别的 95% 置信区间的须线。

Answer 1

* Example generated by -dataex-. For more info, type help dataex
clear
input float(id sept_outhouse sept_inhouse oct_outhouse oct_inhouse)
 1 1 1 1 1
 2 2 2 2 2
 3 3 3 3 3
 4 4 3 3 3
 5 4 4 3 3
 6 4 4 3 3
 7 4 4 4 1
 8 1 1 1 1
 9 1 1 1 1
10 1 1 1 1
end
label values sept_outhouse codes
label values sept_inhouse codes
label values oct_outhouse codes
label values oct_inhouse codes
label def codes 1 "yes", modify
label def codes 2 "no", modify
label def codes 3 "don't know", modify
label def codes 4 "refused", modify

save tokenexample, replace 

rename (*house) (house*)
reshape long house, i(id) j(which) string 
replace which = subinstr(proper(which), "_", " ", .)
gen yes = house == 1
label def WHICH 1 "Sept Out" 2 "Sept In" 3 "Oct Out" 4 "Oct In"
encode which, gen(WHICH) label(WHICH)
statsby, by(WHICH) clear: ci proportion yes, jeffreys 

set scheme s1color 
twoway scatter mean WHICH ///
|| rspike ub lb WHICH, xla(1/4, noticks valuelabel) xsc(r(0.9 4.1)) ///
xtitle("") legend(off) subtitle(Proportion Yes with 95% confidence interval)

这必须向后解决。

1. 必须使用 twoway 绘制均值和置信区间，因为 graph bar 在这里是一个死胡同，因为它也不允许出现胡须。

2. 置信限必须在图形之前放入变量中。一些图形命令，特别是 graph bar，会为你计算均值，但如前所述，这是一个死胡同。所以，我们也需要计算均值。

3. 为此，您需要一个指示变量是。

4. 我所知道的获得结果的最佳方法是将 reshape 应用于不同的结构，然后在 ci proportion 下应用 statsby。

作为一个细节，选项 jeffreys 是明确的，表明存在不同的置信区间计算方法。你应该在知情的情况下选择一个。