Question

我试图将任意数量的分布式高斯曲线拟合到一个函数中 - 每个函数都有自己的参数集。目前，如果我想使用20个函数，我会执行以下操作

φ[α_?NumberQ, x_?NumberQ, xi_?NumberQ, c_?NumberQ] := (
  c E^(- α (x - xi)^2/2))/Sqrt[α/π];
Data := Table[{n/50, N[f[n/50]]}, {n, -300, 300}];

model = φ[a1, x, x1, c1] + φ[a2, x, x2, c2] + φ[a3, x, x3, c3] + 
   φ[a4, x, x4, c4] + φ[a5, x, x5, c5] + φ[a6, x, x6, c6] + 
   φ[a7, x, x7, c7] + φ[a8, x, x8, c8] + φ[a9, x, x9, c9] + 
   φ[a10, x, x10, c10] + φ[a11, x, x11, c11] + φ[a12, x, x12, c12] + 
   φ[a13, x, x13, c13] + φ[a14, x, x14, c14] + φ[a15, x, x15, c15] + 
   φ[a16, x, x16, c16] + φ[a17, x, x17, c17] + φ[a18, x, x18, c18] + 
   φ[a19, x, x19, c19] + φ[a20, x, x20, c20];
nlm = NonlinearModelFit[Data, 
   model, {a1, x1, c1, a2, x2, c2, a3, x3, c3, a4, x4, c4, a5, x5, c5, a6, x6,
     c6, a7, x7, c7, a8, x8, c8, a9, x9, c9, a10, x10, c10, a11, x11, c11, 
     a12, x12, c12, a13, x13, c13, a14, x14, c14, a15, x15, c15, a16, x16, c16,
     a17, x17, c17, a18, x18, c18, a19, x19, c19, a20, x20, c20}, x];

这很好用，但手动创建这些线性组合是很繁琐的。用a，xi和c的系数向量创建函数的线性组合将是很棒的。我只是不确定如何处理这个问题，我希望你们能够对此提供一些见解。

最佳，

托马斯

Answer 1

您可以尝试：

Phi[α_, x_, xi_, c_] := (c E^(- α (x - xi)^2/2))/Sqrt[α/π];

model = Sum[Phi[a@i, x, xx@i, c@i], {i, 20}];

nlm = NonlinearModelFit[Data, model, Flatten@Table[{a@i, xx@i, c@i}, {i, 20}], x]

修改

没有经过测试，但我认为，为了让高斯人的数量保持不变，你也可以这样做：

nlm[n_] := NonlinearModelFit[Data, Sum[Phi[a@i, x, xx@i, c@i], {i, n}] Flatten@Table[{a@i, xx@i, c@i}, {i, n}], x]; nlm[20]

Answer 2

我之前做过这样的事情：

params = Flatten[
   Table[{Subscript[a, i], Subscript[m, i], Subscript[c, i]}, {i, 1, 
     n}]];
model = Sum[
   Phi[Subscript[a, i], x, Subscript[m, i], Subscript[c, i]], {i, 1, 
    n}];
fit = NonlinearModelFit[data, model, params, x]];

只需用你需要的高斯数替换n。显然，如果你有不同的基函数，你将不得不做其他的事情，但是当你只使用一组（甚至两个）基函数时，这很有效。

以下是概念代码的一些证明：

Phi[x_, a_, b_, c_] := c Exp[-(x - a)^2/b^2]/(b Sqrt[\[Pi]])

n = 10;
Ap = RandomReal[{-5, +5}, {n}];
Bp = RandomReal[{0.2, 2}, {n}];
Cp = RandomReal[{-3, +3}, {n}];
f[x_] := Evaluate[Sum[Phi[x, Ap[[i]], Bp[[i]], Cp[[i]]], {i, n}]]

data = Module[{x, y},
   x = RandomReal[{-10, +10}, {3000}];
   y = f[x];
   Transpose[{x, y}]];
(* Force data to be precision to be 50 digits, so we can use higher precision in NLMF *)
data = N[Round[data * 10^50] / 10^50, 50];


params = Flatten@Table[{a@i, b@i, c@i}, {i, n}];
model = Sum[Phi[x, a@i, b@i, c@i], {i, n}];
fit = Normal@NonlinearModelFit[data, model, params, x, WorkingPrecision->50];

Show[ListPlot[data, PlotStyle -> Red], Plot[fit, {x, -5, +5}], 
 PlotRange -> All]

Mathematica中的函数总和

2 个答案: