Question

嗨我有一个散列，其中键是3digit代码，值是该代码下的元素数。我想总结3digit代码并乘以元素数量，然后最后添加它们。例如：

000 23
012 42
222 34

[(0+0+0)*23]+[(0+1+2)*42]+[(2+2+2)*34]=0+126+204=330

所以我试过

foreach my $key (sort keys %hash ){      
@arrSum=split(//, $key);
   foreach $i (@arrSum){    
     $sum+=$i;
     $value=$sum*$hash{$key};
   }    
}

它不起作用。它实际上必须考虑每一行，而是一次性总结所有3digit代码。需要一些帮助。

Answer 1

以下是functional解决问题的方法，它还使用List::Util中的sum：

use List::Util qw(sum);

my %hash = qw(
    000 23
    012 42
    222 34
);

print sum(map { sum(split //) * $hash{$_} } keys %hash);     # 330

Answer 2

我对您的代码做了一些小改动，我得到了正确的值：

#!/usr/bin/perl

use strict;
use warnings;

my %hash = (
   "000" => 23,
   "012" => 42,
   "222" => 34,
);

my $value = 0;
for my $key (sort keys %hash )
{  
   my $sum = 0;
   my @arrSum = split(//, $key);
   for my $i (@arrSum)
   {    
     $sum += $i;
   }
   $value += $sum * $hash{$key};
}

print "$value\n";

Answer 3

（a + b + c）* d =（a * d）+（b * d）+（c * d），所以你可以做到

my $value;
for my $key (keys %hash) {      
   for my $digit (split(//, $key)) {
      $value += $digit * $hash{$key};
   }    
}

但看起来你正在努力：

my $value;
for my $key (keys %hash) {      
   my $sum;
   $sum += $_ for split(//, $key);
   $value += $sum * $hash{$key};
}

或多或少相同：

use List::Util qw( sum );

my $value;
for my $key (keys %hash) {      
   $value += sum(split(//, $key)) * $hash{$key};
}

Answer 4

这个问题似乎是为each量身定做的：

#!/usr/bin/perl

use warnings; use strict;
use List::Util qw( sum );

my %hash = (
   "000" => 23,
   "012" => 42,
   "222" => 34,
);

my $total;
while ( my ($key, $val) = each %hash ) {
    $total += sum(split //, $key) * $val;
}

print "$total\n";

如何总结哈希的元素？

4 个答案: