Question

我正在支持最大RGBA8渲染目标（iOS）的GLES2平台上做一些GPGPU。我需要输出+/- 2.0范围内的vec2，并且能够获得尽可能高的精度，所以我试图将每个组件打包成8位输出的两个组件。

一个重要的要求是解码+编码往返保留编码值。我当前的解决方案不具有此属性，因此我的值在整个地方漂移。

这就是我现在所拥有的（它有点冗长，因为我还在考虑它）：

const float fixed_scale = 4.0;

lowp vec4 encode_fixed(highp vec2 v) {
  vec2 scaled = 0.5 + v/fixed_scale;       // map to range 0..1
  vec2 low = fract(scaled * 255.0);        // extract low order part
  vec2 high = scaled - low/255.0;          // subtract low from high order part

  return vec4(low.x,high.x,low.y,high.y);  // pack into rgba8
}

vec2 decode_fixed(highp vec4 v) {
  vec2 scaled = v.yw + v.xz/255.0;         // recombine low and high parts
  return (scaled - 0.5) * fixed_scale;     // map back to original range
}

编辑：更简单的代码，但仍然漂移

Answer 1

我认为这会对你有所帮助：

vec4 PackFloat8bitRGBA(float val) {
    vec4 pack = vec4(1.0, 255.0, 65025.0, 16581375.0) * val;
    pack = fract(pack);
    pack -= vec4(pack.yzw / 255.0, 0.0);
    return pack;
}

float UnpackFloat8bitRGBA(vec4 pack) {
    return dot(pack, vec4(1.0, 1.0 / 255.0, 1.0 / 65025.0, 1.0 / 16581375.0));
}

vec3 PackFloat8bitRGB(float val) {
    vec3 pack = vec3(1.0, 255.0, 65025.0) * val;
    pack = fract(pack);
    pack -= vec3(pack.yz / 255.0, 0.0);
    return pack;
}

float UnpackFloat8bitRGB(vec3 pack) {
    return dot(pack, vec3(1.0, 1.0 / 255.0, 1.0 / 65025.0));
}

vec2 PackFloat8bitRG(float val) {
    vec2 pack = vec2(1.0, 255.0) * val;
    pack = fract(pack);
    pack -= vec2(pack.y / 255.0, 0.0);
    return pack;
}

float UnpackFloat8bitRG(vec2 pack) {
    return dot(pack, vec2(1.0, 1.0 / 255.0));
}

请注意消除硬件偏差：pack -= vec4(pack.yzw / 255.0, 0.0) - 非常感谢Aras Pranckevičius

Answer 2

好的，我会回答我自己的问题。这似乎有效 - 它没有漂移，但视觉效果看起来有点不准确。注意解码器中的舍入，这是必要的。

const float fixed_scale = 4.0;

lowp vec4 encode_fixed(highp vec2 v) {
  vec2 scaled = 0.5 + v/fixed_scale;
  vec2 big = scaled * 65535.0/256.0;
  vec2 high = floor(big) / 255.0;
  vec2 low = fract(big);

  return vec4(low.x,high.x,low.y,high.y);
}

vec2 decode_fixed(highp vec4 v) {
  v = floor(v * 255.0 + 0.5);
  vec2 scaled = vec2(v.yw * 256.0 + v.xz) / 65535.0;
  return (scaled - 0.5) * fixed_scale;
}

GLES2着色器的高精度输出

2 个答案: