Question

我想在XSLT中实现一个split function/template，它将字符串和分隔符作为输入，并返回字符串的拆分数组。

或者更确切地说，我希望能够按照以下方式做点什么：

<xsl:call-template name="F">
    <xsl:with-param name="input" select="'a,b,c,d,e'"/>
    <xsl:with-param name="replacement">
    <option value='$x'>$x</option>
</xsl:with-param>
</xsl:call-template>

会给我

<option value='a'>a</option><option value='b'>b</option><option value='c'>c</option><option value='d'>d</option><option value='e'>e</option>

针对XSLT 1.0的问题（但我不介意学习XSLT 2.0是如何做到的）

Answer 1

<强>予。 XSLT 2.0解决方案

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
  <xsl:variable name="vStr" select="'a,b,c,d,e'"/>

  <xsl:for-each select="tokenize($vStr, ',')">
   <option value="{.}"><xsl:value-of select="."/></option>
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于ant XML文档（未使用）时，会生成所需的正确结果：

<option value="a">a</option>
<option value="b">b</option>
<option value="c">c</option>
<option value="d">d</option>
<option value="e">e</option>

解释：使用标准XPath 2.0函数 tokenize() 。

<强> II。 XSLT 1.0：使用FXSL 1.x str-split-to-words函数/模板

此XSLT 1.0转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 exclude-result-prefixes="ext">
  <xsl:import href="strSplit-to-Words.xsl"/>
  <xsl:output indent="yes" omit-xml-declaration="yes"/>

    <xsl:template match="/">
      <xsl:variable name="vwordNodes">
        <xsl:call-template name="str-split-to-words">
          <xsl:with-param name="pStr" select="/"/>
          <xsl:with-param name="pDelimiters"
                          select="', '"/>
        </xsl:call-template>
      </xsl:variable>

      <xsl:apply-templates select=
       "ext:node-set($vwordNodes)/*"/>
    </xsl:template>

    <xsl:template match="word">
     <option value="{.}"><xsl:value-of select="."/></option>
    </xsl:template>
</xsl:stylesheet>

应用于此XML文档时：

<t>a,b,c d,e</t>

生成想要的正确结果：

<option value="a">a</option>
<option value="b">b</option>
<option value="c">c</option>
<option value="d">d</option>
<option value="e">e</option>

请注意 pDelimiters参数（如其名称所示）可以包含多个分隔字符 - 在这种情况下，我们同时使用','和{{1} }。

<强> III。 XSLT 1.0解决方案使用手写递归命名模板：

这种转变：

' '

应用于此XML文档时：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="text()" name="tokenize">
  <xsl:param name="pText" select="."/>
  <xsl:param name="pDelim" select="','"/>

  <xsl:if test="string-length($pText) > 0">
    <xsl:variable name="vToken" select=
    "substring-before(concat($pText,','), ',')"/>

    <option value="{$vToken}">
      <xsl:value-of select="$vToken"/>
    </option>

    <xsl:call-template name="tokenize">
     <xsl:with-param name="pText" select=
      "substring-after($pText,',')"/>
    </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

生成想要的正确结果：

<t>a,b,c,d,e</t>

<强> IV。传递给上面的III中的<option value="a">a</option> <option value="b">b</option> <option value="c">c</option> <option value="d">d</option> <option value="e">e</option>模板作为参数，模板/函数来处理每个令牌

tokenize

当此转换应用于与III中相同的XML文档时，会产生相同的，想要的，正确的结果：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:f="http://fxsl.sf.net" exclude-result-prefixes="f">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <f:processToken/>

 <xsl:variable name="vFunc" select=
  "document('')/*/f:processToken[1]"/>

 <xsl:template match="text()" name="tokenize">
  <xsl:param name="pText" select="."/>
  <xsl:param name="pDelim" select="','"/>
  <xsl:param name="pProcessFunc" select="$vFunc"/>

  <xsl:if test="string-length($pText) > 0">
    <xsl:variable name="vToken" select=
    "substring-before(concat($pText,','), ',')"/>

    <xsl:apply-templates select="$pProcessFunc">
     <xsl:with-param name="arg1" select="$vToken"/>
    </xsl:apply-templates>

    <xsl:call-template name="tokenize">
     <xsl:with-param name="pText" select=
      "substring-after($pText,',')"/>
    </xsl:call-template>
  </xsl:if>
 </xsl:template>

 <xsl:template match="f:processToken">
  <xsl:param name="arg1"/>
    <option value="{$arg1}">
      <xsl:value-of select="$arg1"/>
    </option>
 </xsl:template>
</xsl:stylesheet>

现在，如果我们用最后一个模板替换：

<option value="a">a</option>
<option value="b">b</option>
<option value="c">c</option>
<option value="d">d</option>
<option value="e">e</option>

再次产生所需的结果：

 <xsl:template match="f:processToken">
  <xsl:param name="arg1"/>
    <p>
      <xsl:value-of select="$arg1"/>
    </p>
 </xsl:template>

Answer 2

您看到的答案只是缺少 分隔符 参数：

<xsl:template name="output-tokens">
    <xsl:param name="list" />
    <xsl:param name="delimiter" />
    <xsl:variable name="newlist">
        <xsl:choose>
            <xsl:when test="contains($list, $delimiter)"><xsl:value-of select="normalize-space($list)" /></xsl:when>

            <xsl:otherwise><xsl:value-of select="concat(normalize-space($list), $delimiter)"/></xsl:otherwise>
        </xsl:choose>
    </xsl:variable>
    <xsl:variable name="first" select="substring-before($newlist, $delimiter)" />
    <xsl:variable name="remaining" select="substring-after($newlist, $delimiter)" />
    <xsl:value-of select="$first" /> <!-- token -->
    <xsl:if test="$remaining">
        <xsl:call-template name="output-tokens">
            <xsl:with-param name="list" select="$remaining" />
            <xsl:with-param name="delimiter"><xsl:value-of select="$delimiter"/></xsl:with-param>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

我想实现一个`split function / template`，它将字符串和分隔符作为输入，并返回字符串的split数组

2 个答案: