Question

我需要解决序言问题。

问题文本为：写一个谓语Prolog，称为Labyrinth（Lab，From，To），该谓词Prolog在输入中接收迷宫，初始位置和结束位置，并打印可能的动作列表（上，右，下，左）。迷宫是一个7x7矩阵，具有行列表和列列表。如果是墙，则每个单元格包含“ w”，如果为空，则包含“ e”。起始和结束位置用in / 2函数描述，该函数的参数为行和列。

这是矩阵的一个示例（索引从0开始）

Labyrinth([
    [e,e,w,w,w,w,w],           
    [w,e,w,e,w,e,w],
    [w,e,w,e,w,e,w],
    [w,e,e,e,w,e,w],
    [w,e,w,e,w,e,w],
    [w,e,e,e,e,e,w],
    [e,w,w,w,w,e,e]
    ], in(0,0), in(6,6)

我了解需要：

四个谓词，每一个谓词（上，下，左，右）；
一个测试当前单元格是=='w'还是=='e';
目标测试，以检查当前位置是否为最终位置

我坚持写正确的顺序并断言要解决问题。有人有提示吗？

/ *******更新****************** / @CapelliC这是我的代码。我想写必要的谓词，但我陷入了回溯之中

get_cell([R,C], Data,L):-
    nth1(R,Data,L1),
    nth1(C,L1,L).

labyrinth(Map, Start, Finish, Move) :-

   move(Start, Move),
   update(Start, Move, NewState),
   legal(NewState, Map),
   \+ member(NewState, Finish),
   labyrinth(Map, NewState, [NewState|Finish], Move).

legal( p(X,Y), Map) :-
   X > 0,
   Y > 0,
   get_cell([X,Y], Map, Z),
   %write(Z),
   Z \= w .

% UP
update(  p(X, Y), up, p(X_new, Y)  ) :-
    write('up '),
    X_new is X - 1.

% DOWN
update(  p(X,Y), down, p(X_new, Y) ) :-
    write('down '),
    X_new is X + 1.

% LEFT
update(  p(X,Y), left, p(X, Y_new)  ) :-
   write('left '),
   Y_new is Y - 1.

% RIGHT
update(  p(X,Y), right, p(X, Y_new)  ) :-
   write('right '),
   Y_new is Y + 1.

move(  p( _, _ ), up    ).
move(  p( _, _ ), down  ).
move(  p( _, _ ), left  ).
move(  p( _, _ ), right ).

我这样调用程序：

labyrinth([
   [e,e,w,w,w,w,w],           
   [w,e,w,e,w,e,w],
   [w,e,w,e,w,e,w],
   [w,e,e,e,w,e,w],
   [w,e,w,e,w,e,w],
   [w,e,e,e,e,e,w],
   [e,w,w,w,w,e,e]
], p(1,2), p(6,6), _)

Answer 1

一些总体变化，这可能是在迷宫中实现回溯的一种方式。还有一个额外的位置列表，可以跟踪以前是否曾访问过一个位置，如果迷宫中没有周期，那么就没有必要了。

get_cell([R,C], Data,L):-
    nth0(R,Data,L1),
    nth0(C,L1,L).

labyrinth(Map, Start, Finish):-
    labyrinth(Map, Start, Finish,[], [],Solution),!,
    reverse(Solution,S),
    print(S).

labyrinth(_, Finish, Finish,_, Out,Out). %Unification of solution
labyrinth(Map, Start, Finish, Positions,Moves,Out) :-
move(Move),
update(Start, Move, NewState),
\+ member(NewState, Positions),
legal(NewState, Map),
labyrinth(Map, NewState, Finish,[NewState|Positions],[Move|Moves],Out).

legal( p(X,Y), Map) :-
X >= 0, 7>X,
Y >= 0, 7>Y,
get_cell([X,Y], Map, Z),
%write(Z),
Z \= w .

% UP
update(  p(X, Y), up, p(X_new, Y)  ) :-
    X_new is X - 1.

% DOWN
update(  p(X,Y), down, p(X_new, Y) ) :-
    X_new is X + 1.

% LEFT
update(  p(X,Y), left, p(X, Y_new)  ) :-
Y_new is Y - 1.

% RIGHT
update(  p(X,Y), right, p(X, Y_new)  ) :-
Y_new is Y + 1.

move(  up    ).
move(  down  ).
move(  left  ).
move(  right ).

Prolog-解决迷宫

1 个答案: