Question

使用以下列表

list = {{a, b, c, d}, {1, 2, 3, 4}, {5, 6, 7, 8}};

是否可以选择第二个值> 3的列表。期望输出

{5, 6, 7, 8}

调整以下代码，该代码当前提取列表中的所有值＆gt;

Select[#, # > 2 &] & /@ list[[2 ;;]

可以在Conditional Data Manipulation in Mathematica

找到复杂的查询解决方案

Answer 1

或者，使用Select

Select[list, #[[2]] > 3 &]

输出

{{5, 6, 7, 8}}

Answer 2

在这种情况下，Select是最简单的方法，但Pick在相关问题中也很有用。

list = {{a, b, c, d}, {1, 2, 3, 4}, {5, 6, 7, 8}};

Pick[list, #>3& /@ list[[All, 2]] ]

为了解释，Pick采用相同形状的两个列表（或嵌套列表），并返回第一个中相应元素为True的每个元素。（它也可以接受第三个参数来匹配True以外的元素。）

此处，使用list[[All, 2]]提取第二列，然后将测试#>3&映射到每个元素。然后将其用作选择列表。

响应500的评论，要求推广Select方法：

selectByColumn[array_, index_, value_, range_] :=
  Select[array, #[[index]] > value &][[All, range]]

这允许指定：

array：要从
index：比较的列索引
value：要与
range：从每个结果行中提取的Part规范

Answer 3

不同解决方案的速度比较

有趣的是，Select对于解压缩的数组总是工作得更快，对于大型数组，差异大约是一个数量级！点击下表放大：

时序测试代码：

solutions = Hold[
   Select[list, #[[2]] > 3 &],
   Cases[list, _List?(#[[2]] > 3 &)],
   Cases[list, x_List /; x[[2]] > 3],
   Cases[list, {_, x_, ___} /; x > 3],
   Cases[list, {_, _?(# > 3 &), ___}],
   Cases[list, {x___} /; List[x][[2]] > 3],
   Pick[list, UnitStep[list[[All, 2]] - 3], 1],
   Pick[list, # > 3 & /@ list[[All, 2]]]
   ];
testCases = Hold[
   {"Packed Reals", RandomReal[{0, 5}, {dim, dim}]},
   {"Unpacked Reals", 
    Developer`FromPackedArray@RandomReal[{0, 5}, {dim, dim}]},
   {"Packed Integers", RandomInteger[{0, 5}, {dim, dim}]},
   {"Unpacked Integers", 
    Developer`FromPackedArray@RandomInteger[{0, 5}, {dim, dim}]},
   {"Rationals", 
    Rationalize[#, .001] & /@ RandomReal[{0, 5}, {dim, dim}]}
   ];
timing := 
  Function[Null, 
   If[(time = First[Timing[Do[#;, {n}]]]) < .3, 
     Print["Too small timing for ", n, " iterations (dim=", dim, 
      ") of ", HoldForm[#], ": ", time, " seconds!"]; time, time]/n, 
   HoldFirst];
generateTable := 
 Labeled[TableForm[
   Transpose@
    Table[list = testCases[[i, 2]]; 
     tmgs = List @@ (timing /@ solutions); 
     d = Last@MantissaExponent[Min[tmgs]] - 3; 
     Row[{Round[10^-d*#], ".\[Times]", Superscript[10, d]}] & /@ 
      tmgs, {i, 1, Length[testCases]}], 
   TableHeadings -> {List @@ (HoldForm /@ solutions), 
     List @@ testCases[[All, 1]]}, TableAlignments -> Right], 
  Row[{"Average timings for ", dim, "\[Times]", dim, " list"}], Top]

Column[{dim = 5; n = 30000; generateTable, dim = 100; n = 3000; 
  generateTable, dim = 1000; n = 150; generateTable}, Left, 1, 
 Frame -> All, FrameStyle -> Gray]

Answer 4

备用案例语法。跳过第一项，第二项被测试为＆gt; 3，我们不关心列表的其余部分：

In[45]:= Cases[list, {_, _?(# > 3 &), ___}]
Out[45]= {{5, 6, 7, 8}}

我怀疑这会比Select更快，但有时更清晰，特别是如果测试涉及不同的数据类型或匹配某些子结构。

Answer 5

编辑：

如Alexey所述，Mathematica中的以下结构比我早期的解决方案更具惯用性

Cases[list, x_List /; x[[2]] > 2]

和

Cases[list, _List?(#[[2]] > 2 &)]

一种解决方案是使用Cases

Cases[list, {_, x_, ___} /; x > 2]
Out[1] = {{5, 6, 7, 8}}

如果你想（比如说）检查第95个元素是否是＆gt;这没有用。 2.因此，这是一种更好的方法，您可以轻松指定位置：

Cases[list, {x___} /; List[x][[2]] > 2]
Out[2] = {{5, 6, 7, 8}}

在Mathematica中选择条件查询

5 个答案:

不同解决方案的速度比较

编辑：