Question

我有用于测试Java应用程序的Spock集成测试。对于其中一种方法，调用将转到实际方法“ bMethod（）”，而不是返回存根的值。它对于另一个方法'aMethd（）'正常工作，并返回存根值，而不调用实际方法。这两种方法都属于Calc类。有没有办法调查Spock在做什么以及为什么？

public interface CalcIntf {
  public int aMethod(int a, int b);      
  public int bMethod(int a, int b, int c);
}

MyTestSpec extends Specification {
    def "aMethod test"() {
        given:
          ...
          CalcIntf calcIntf = Mock(CalcIntf)
          calcIntf.aMethod(_,_) >> { return 100; }
        when:
          //service call
        then:
          // asserts go here
    }

    def "bMethod test"() {
        given:
          ...
          CalcIntf calcIntf = Mock(CalcIntf)
          calcIntf.bMethod(_,_,_) >> { return 100; }
        when:
          // service call
        then:
          // asserts go here
    }
}

Answer 1

尝试类似

given: 'a math with a calculator that always returns 100'
    def calc = Stub(CalcIntf) {
        bMethod(_,_,_) >> 100
    }
    def math = new Math(calc)

when: 'the math is asked to calculate something'
    def result = math.m2()

then: 'it returns 100'
    result == 100

注意事项：

返回到存根的返回值应该是返回值，而不是闭包
您必须通过构造函数或其他方式在数学中设置存根计算
您在数学上调用的方法不带参数

Answer 2

具有最少修复的原始代码

因此，我首先使m1和m2返回int而不是void。然后至少您可以检查结果。然后，我还要确保正确调用那些没有参数的方法，就像克里斯已经提到的那样。所以现在代码看起来像这样：

package de.scrum_master.stackoverflow.q62269054

import spock.lang.Specification

class MyTestSpec extends Specification {
  def "testing addition using aMethod"() {
    given:
    Math math = new Math()
    CalcIntf calcIntf = Mock(CalcIntf)
    calcIntf.aMethod(_, _) >> { return 123 }
    expect:
    math.m1() == 123
  }

  def "testing addition using bMethod"() {
    given:
    Math math = new Math()
    CalcIntf calcIntf = Mock(CalcIntf)
    calcIntf.bMethod(_, _, _) >> { return 456 }
    expect:
    math.m2() == 456
  }

  interface CalcIntf {
    int aMethod(int a, int b)

    int bMethod(int a, int b, int c)
  }

  static class Calc implements CalcIntf {
    int aMethod(int a, int b) {
      return a + b
    }

    int bMethod(int a, int b, int c) {
      return a + b + c
    }
  }

  static class Math {
    Calc calc = new Calc()

    int m1() {
      calc.aMethod(1, 2)
    }

    int m2() {
      calc.bMethod(1, 2, 3)
    }
  }
}

当然，测试失败：

Condition not satisfied:

math.m1() == 123
|    |    |
|    3    false
...

Condition not satisfied:

math.m2() == 456
|    |    |
|    6    false
...

失败的原因是您没有在任何地方注入模拟，但是Math通过Calc使用了硬编码的Calc calc = new Calc()实例。

通过测试

因此，我们需要一种注入模拟的方法，例如通过构造函数或setter。您还应该将字段类型从Calc更改为CalcIntf，因为否则将无法注入接口模拟。如果不在代码中使用接口，而是针对具体的子类编写代码，为什么还要创建接口？

package de.scrum_master.stackoverflow.q62269054

import spock.lang.Specification

class MyTestSpec extends Specification {
  def "testing addition using aMethod"() {
    given:
    CalcIntf calcIntf = Mock(CalcIntf)
    calcIntf.aMethod(_, _) >> { return 123 }
    Math math = new Math(calcIntf)
    expect:
    math.m1() == 123
  }

  def "testing addition using bMethod"() {
    given:
    CalcIntf calcIntf = Mock(CalcIntf)
    calcIntf.bMethod(_, _, _) >> { return 456 }
    Math math = new Math(calcIntf)
    expect:
    math.m2() == 456
  }

  interface CalcIntf {
    int aMethod(int a, int b)

    int bMethod(int a, int b, int c)
  }

  static class Calc implements CalcIntf {
    int aMethod(int a, int b) {
      return a + b
    }

    int bMethod(int a, int b, int c) {
      return a + b + c
    }
  }

  static class Math {
    CalcIntf calcIntf

    Math(CalcIntf calcIntf) {
      this.calcIntf = calcIntf
    }

    int m1() {
      calcIntf.aMethod(1, 2)
    }

    int m2() {
      calcIntf.bMethod(1, 2, 3)
    }
  }
}

您描述的测试行为

因此，现在测试通过了，但它们不会重现您描述的行为：

对于其中一种方法，调用将转到实际方法'bMethod（）'，而不是返回存根的值。

我可以想象发生这种情况的一个原因：您想存根的方法是final，这意味着实现模拟的动态代理无法覆盖它，因此也就不存根。但这与您在代码中描述的情况完全不同。

看到了吗？如果您的示例代码不能重现该问题，则完全没有用，这就是为什么在我的评论中我告诉您始终提供MCVE而不提供某些随机伪代码。如果有人报告您代码中的错误，您还想知道如何重现它。

因此，为了重现您报告的问题，我必须做出有根据的猜测，因为您的代码没有帮助。只需更改先前版本中的以下内容：

int bMethod(int a, int b, int c)→final int bMethod(int a, int b, int c)
Mock(CalcIntf)→Mock(Calc)在2个地方

现在测试结果为：一种通过和一种失败的特征方法：

Condition not satisfied:

math.m2() == 456
|    |    |
|    6    false
...

Spock模拟调用模拟类的真实方法

2 个答案:

具有最少修复的原始代码

通过测试

您描述的测试行为