原始代码，稍作审核

Question

底部的程序应该返回缺少可证明目标的子句。问题是它返回一个解决方案“太多”，如此输出中的最后一个解决方案所示：

?- main.
MISSING PREMISES:
p(A,2,presenceOfFlammableMaterial)
p(B,2,johnDroppedAMatch)
true ;

MISSING PREMISES:
p(A,2,presenceOfFlammableMaterial)
p(B,1,johnWasTired)
true ;

MISSING PREMISES:
precedes(3,3)
p(A,3,presenceOfFlammableMaterial)
p(B,2,johnWasTired)
true ;
false.

我想要的只是：

MISSING PREMISES:
p(A,2,presenceOfFlammableMaterial)
p(B,2,johnDroppedAMatch)
true ;

MISSING PREMISES:
p(A,2,presenceOfFlammableMaterial)
p(B,1,johnWasTired)
true ;

我很难理解问题所在，不胜感激一些改进的技巧（-），或者一些文学技巧（我已经很熟悉Triska的出色网页）。重要谓词为missing0（G，M），其中G是目标，M是缺失子句的列表。我对此问题的怀疑之一是，可能有无限数量的子句失败，因此我缺少某种“停止”条件。

我在SWI Prolog论坛上发布了相同的question，但没有得到任何回应。我正在运行SWI Prolog。

干杯/ JCR

程序---------------------------------------------- -------------------------------------------

:-use_module(library(clpr)).

precedes(1, 2).
precedes(2, 3).

p(X1, T2, johnDroppedAMatch):-
    p(X2, T1, johnWasTired),
    precedes(T1, T2),
    {X1 = 0.5 * X2}.

p(X1, T2, fire):-
    p(X2, T1, presenceOfFlammableMaterial),
    p(X3, T1, johnDroppedAMatch),
    precedes(T1, T2),
    {X1 = 0.7 * X2 * X3}.

missing(G, M):- call(G), M = ['There are no missing premises.'].
missing(G, M):- \+clause(G, _), M = ['There are no clauses for the goal.'].
missing(G, M):- clause(G, B), \+G, missing0(B, M).

missing0(G, M):- G = (G1, G2), !, missing0(G1, M1), missing0(G2, M2), append(M1, M2, M).  %Look for missing clauses in a conjunction
missing0(G, M):- G = (G1; _), missing0(G1, M). %Look for missing clauses in a disjunction 
missing0(G, M):- G = (_; G2), missing0(G2, M). %Look for missing clauses in a disjunction
missing0(G, M):- call(G), M = []. %If G is callable then it is not missing
missing0(G, M):- \+G, G \= (_, _), G \= (_; _), M = [G]. %G fails, and is neither a conjunction nor a disjunction, so put in in M. Here i collect missing clauses.
missing0(G, M):- \+G, G \= {_}, clause(G, B), missing0(B, M). %If G fails and if G1 is in the body of G, check what predicates are missing for G1 to be provable. G \= {_} is to avoid an error when using clause/2 on clpr predicates.

showMissing(M):- copy_term_nat(M, M1), numbervars(M1, 0, _, [attvar(bind)]), sort(M1, M2), nl, writeln('MISSING PREMISES:'), maplist(writeln, M2).

main:-missing(p(1, 3, fire), M), showMissing(M).

Answer 1

这不是一个答案，但是我在代码方面做了一些尝试，添加了一些打印输出，并使其更具确定性。现在，它报告了一个解决方案。

原始代码，稍作审核

这是原始代码，带有一些打印输出。它报告的方式与以前完全相同，其输出未排序为能够追踪其首先命中的内容。

:-use_module(library(clpr)).

% ======================
% knowledge
% ======================

% time is ordered
% Note: Time is not transitive as precedes(1,3) is missing!

precedes(1, 2).
precedes(2, 3).

p(X1, T2, johnDroppedAMatch):-
    p(X2, T1, johnWasTired),
    precedes(T1, T2),
    {X1 = 0.5 * X2}.

p(X1, T2, fire):-
    p(X2, T1, presenceOfFlammableMaterial),
    p(X3, T1, johnDroppedAMatch),
    precedes(T1, T2),
    {X1 = 0.7 * X2 * X3}.

% ======================
% reasoning about knowledge
% ======================

% Note: What exactly does it mean for a premise to be "missing"?
% Are variables to be resolved when reporting? 

missing(G, M) :- call(G), 
                 M = ['There are no missing premises.'].

missing(G, M) :- \+clause(G, _),
                 M = ['There are no clauses for the goal.'].

missing(G, M) :- clause(G, B), \+G, missingr(B, M, 0).

% --- Recursively look for missing stuff in a goal 
% D is the Depth of the analysis
% SP is a string of spaces for indentation

missingr(G, M, D) :- G = (G1, G2), !,
                     sp(D,SP), format("~w«~w» AND «~w»\n",[SP,G1,G2]), spinc(D,DP),
                     missingr(G1, M1, DP), 
                     missingr(G2, M2, DP),                  
                     append(M1, M2, M).

missingr(G, M, D) :- G = (G1; _), !,
                     sp(D,SP), format("~w«~w» OR «~w»\n",[SP,G1,"..."]), spinc(D,DP),
                     missingr(G1, M, DP).

missingr(G, M, D) :- G = (_ ; G2), !,
                     sp(D,SP), format("~w«~w» OR «~w»\n",[SP,"...",G2]), spinc(D,DP),
                     missingr(G2, M, DP).

missingr(G, M, D) :- sp(D,SP), format("~wMaybe «~w» can be called?\n",[SP,G]),
                     call(G),
                     format("~w«~w» succeeds; nothing is missing here.\n",[SP,G]),
                     M = [].

missingr(G, M, D) :- \+G, G \= (_,_), G \= (_;_),
                     sp(D,SP), format("~w«~w» is not provable, not a conjunction, not a disjunction: Consider missing!\n",[SP,G]),
                     M = [G].

missingr(G, M, D) :- \+G, G \= {_}, clause(G, B),
                     sp(D,SP), format("~w«~w» is not provable, not a constraint, and a clause with body «~w», continue with body\n",[SP,G,B]), spinc(D,DP),
                     missingr(B, M, DP).

% Igniter

showMissing(M) :- copy_term_nat(M, M1), 
                  numbervars(M1, 0, _, [attvar(bind)]),
                  % sort(M1, M2), % do not sort so that terms are output in found order
                  M2 =  M1,
                  nl, writeln('MISSING PREMISES:'),
                  maplist(writeln, M2).

main :- missing(p(1, 3, fire), M), showMissing(M).


% Generate string of N spaces fast. 

spinc(In,Out) :- Out is In+2.

sp(0,"") :- !.
sp(1,".") :- !.
sp(Len,Str) :- Len > 1,
               Lenx is Len div 2, Remx is Len rem 2, 
               sp(Lenx,Strx), 
               string_concat(Strx,Strx,Stry),
               (Remx == 0 -> Str = Stry ; string_concat(Stry,".",Str)),!.

输出

?- main.  
«p(_7002,_7004,presenceOfFlammableMaterial)» AND «p(_7010,_7004,johnDroppedAMatch),precedes(_7004,3),{1=0.7*_7002*_7010}»
..Maybe «p(_7002,_7004,presenceOfFlammableMaterial)» can be called?
..«p(_7002,_7004,presenceOfFlammableMaterial)» is not provable, not a conjunction, not a disjunction: Consider missing!
..«p(_7010,_7004,johnDroppedAMatch)» AND «precedes(_7004,3),{1=0.7*_7002*_7010}»
....Maybe «p(_7010,_7004,johnDroppedAMatch)» can be called?
....«p(_7010,_7004,johnDroppedAMatch)» is not provable, not a conjunction, not a disjunction: Consider missing!
....«precedes(_7004,3)» AND «{1=0.7*_7002*_7010}»
......Maybe «precedes(_7004,3)» can be called?
......«precedes(2,3)» succeeds; nothing is missing here.
......Maybe «{1=0.7*_7002*_7010}» can be called?
......«{1=0.7*_7914*_7940}» succeeds; nothing is missing here.

MISSING PREMISES:
p(A,2,presenceOfFlammableMaterial)
p(B,2,johnDroppedAMatch)
true ;

....«p(_7010,_7004,johnDroppedAMatch)» is not provable, not a constraint, and a clause with body «p(_7278,_7280,johnWasTired),precedes(_7280,_7004),{_7010=0.5*_7278}», continue with body
......«p(_7278,_7280,johnWasTired)» AND «precedes(_7280,_7004),{_7010=0.5*_7278}»
........Maybe «p(_7278,_7280,johnWasTired)» can be called?
........«p(_7278,_7280,johnWasTired)» is not provable, not a conjunction, not a disjunction: Consider missing!
........«precedes(_7280,_7004)» AND «{_7010=0.5*_7278}»
..........Maybe «precedes(_7280,_7004)» can be called?
..........«precedes(1,2)» succeeds; nothing is missing here.
..........Maybe «{_7010=0.5*_7278}» can be called?
..........«{_8266=0.5*_8368}» succeeds; nothing is missing here.
....«precedes(2,3)» AND «{1=0.7*_7002*_8266}»
......Maybe «precedes(2,3)» can be called?
......«precedes(2,3)» succeeds; nothing is missing here.
......Maybe «{1=0.7*_7002*_8266}» can be called?
......«{1=0.7*_9472*_8266}» succeeds; nothing is missing here.

MISSING PREMISES:
p(A,2,presenceOfFlammableMaterial)
p(B,1,johnWasTired)
true ;

..........«precedes(2,3)» succeeds; nothing is missing here.
..........Maybe «{_7010=0.5*_7278}» can be called?
..........«{_8266=0.5*_8368}» succeeds; nothing is missing here.
....«precedes(3,3)» AND «{1=0.7*_7002*_8266}»
......Maybe «precedes(3,3)» can be called?
......«precedes(3,3)» is not provable, not a conjunction, not a disjunction: Consider missing!
......Maybe «{1=0.7*_7002*_8266}» can be called?
......«{1=0.7*_9476*_8266}» succeeds; nothing is missing here.

MISSING PREMISES:
p(A,3,presenceOfFlammableMaterial)
p(B,2,johnWasTired)
precedes(3,3)
true ;
false.

对此进行思考，现在还不清楚“谓词缺失”是什么意思，甚至不清楚在解释过程中遇到连词或析取词时应该发生的情况。需要更多细节！

修改后的代码尝试

这是经过修改的代码，似乎与所需代码一致，但更具确定性，仅输出一种解决方案：

:-use_module(library(clpr)).

% ======================
% knowledge
% ======================

% time is ordered
% Note: Time is not transitive as precedes(1,3) is missing!

precedes(1, 2).
precedes(2, 3).

p(X1, T2, johnDroppedAMatch):-
    p(X2, T1, johnWasTired),
    precedes(T1, T2),
    {X1 = 0.5 * X2}.

p(X1, T2, fire):-
    p(X2, T1, presenceOfFlammableMaterial),
    p(X3, T1, johnDroppedAMatch),
    precedes(T1, T2),
    {X1 = 0.7 * X2 * X3}.

% ======================
% reasoning about knowledge
% ======================

% Note: What exactly does it mean for a premise to be "missing"?
% Are variables to be resolved when reporting? 

missing(G, M) :- call(G), 
                 M = ['There are no missing premises.'].

missing(G, M) :- \+clause(G, _),
                 M = ['There are no clauses for the goal.'].

missing(G, M) :- clause(G, B), \+G, missingr(B, M, 0).

% --- Recursively look for missing stuff in a goal

% Conjunction
% In a conjunction we can fail on left or right, go down both branches.

missingr(G, M, D) :- G = (G1, G2), !,
                     sp(D,SP), format("~w«~w» AND «~w»\n",[SP,G1,G2]), spinc(D,DP),
                     missingr(G1, M1, DP), 
                     missingr(G2, M2, DP),                  
                     append(M1, M2, M).

% Disjunction. Finagle a proper guard!
% Note: In a disjunction we fail if we fail on both sides, but then what to report???

missingr(G, M, D) :- G = (G1; G2), !,
                     sp(D,SP), format("~w«~w» OR «~w»\n",[SP,G1,G2]), spinc(D,DP),
                     (missingr(G1, M, DP) ; missingr(G2, M, DP)).

% If G is callable and succeeds then it is not missing. 
% The call will unify variables, which may or may not be what we want.

missingr(G, M, D) :- sp(D,SP), format("~wMaybe «~w» can be called?\n",[SP,G]),
                     call(G), !,
                     format("~w«~w» succeeds; nothing is missing here.\n",[SP,G]),
                     M = [].

% If G fails and if B is the body of G, check what predicates are
% missing for B to be provable. G \= {_} is to avoid an error when
% using clause/2 on clpr predicates.

missingr(G, M, D) :- \+G, !, 
                     sp(D,SP), format("~w«~w» is nonprovable\n",[SP,G]), spinc(D,DP),
                     nonprovable(G, M, DP).

nonprovable(G, M, D) :- G \= {_}, clause(G, B), !,
                        sp(D,SP), format("~w«~w» is a nonprovable clause with body «~w», continue with body\n",[SP,G,B]), spinc(D,DP),
                        missingr(B, M, DP). 

nonprovable(G, M, D) :- G \= {_}, !,
                        sp(D,SP), format("~w«~w» is a nonprovable non-clause: considered missing!\n",[SP,G]),
                        M = [G].

nonprovable(G, M, D) :- sp(D,SP), format("~w«~w» is a constraint; dropped!\n",[SP,G]),
                        M = [].

% Igniter

showMissing(M) :- copy_term_nat(M, M1), 
                  numbervars(M1, 0, _, [attvar(bind)]),
                  nl, writeln('MISSING PREMISES:'),
                  maplist(writeln, M1).

main :- missing(p(1, 3, fire), M), showMissing(M).


% Generate string of N spaces fast. 

spinc(In,Out) :- Out is In+2.

sp(0,"") :- !.
sp(1,".") :- !.
sp(Len,Str) :- Len > 1,
               Lenx is Len div 2, Remx is Len rem 2, 
               sp(Lenx,Strx), 
               string_concat(Strx,Strx,Stry),
               (Remx == 0 -> Str = Stry ; string_concat(Stry,".",Str)),!.

新输出

运行它会生成一个解决方案：

?- main.
«p(_5182,_5184,presenceOfFlammableMaterial)» AND «p(_5190,_5184,johnDroppedAMatch),precedes(_5184,3),{1=0.7*_5182*_5190}»
..Maybe «p(_5182,_5184,presenceOfFlammableMaterial)» can be called?
..«p(_5182,_5184,presenceOfFlammableMaterial)» is nonprovable
....«p(_5182,_5184,presenceOfFlammableMaterial)» is a nonprovable non-clause: considered missing!
..«p(_5190,_5184,johnDroppedAMatch)» AND «precedes(_5184,3),{1=0.7*_5182*_5190}»
....Maybe «p(_5190,_5184,johnDroppedAMatch)» can be called?
....«p(_5190,_5184,johnDroppedAMatch)» is nonprovable
......«p(_5190,_5184,johnDroppedAMatch)» is a nonprovable clause with body «p(_5572,_5574,johnWasTired),precedes(_5574,_5184),{_5190=0.5*_5572}», 
........«p(_5572,_5574,johnWasTired)» AND «precedes(_5574,_5184),{_5190=0.5*_5572}»
..........Maybe «p(_5572,_5574,johnWasTired)» can be called?
..........«p(_5572,_5574,johnWasTired)» is nonprovable
............«p(_5572,_5574,johnWasTired)» is a nonprovable non-clause: considered missing!
..........«precedes(_5574,_5184)» AND «{_5190=0.5*_5572}»
............Maybe «precedes(_5574,_5184)» can be called?
............«precedes(1,2)» succeeds; nothing is missing here.
............Maybe «{_5190=0.5*_5572}» can be called?
............«{_6626=0.5*_6728}» succeeds; nothing is missing here.
....«precedes(2,3)» AND «{1=0.7*_5182*_6626}»
......Maybe «precedes(2,3)» can be called?
......«precedes(2,3)» succeeds; nothing is missing here.
......Maybe «{1=0.7*_5182*_6626}» can be called?
......«{1=0.7*_7658*_6626}» succeeds; nothing is missing here.

MISSING PREMISES:
p(A,2,presenceOfFlammableMaterial)
p(B,1,johnWasTired)
true.

但是，正如所说的，我们实际上想在这里拥有什么？

查找目标可证明缺少哪些谓词的程序

1 个答案:

原始代码，稍作审核

输出

修改后的代码尝试

新输出