Question

我想将下面的方法转换为嵌套的FOR而不是嵌套的LOOP，但是由于内部表是动态的，所以我不知道该怎么做（它可以是5种不同类型之一）。

TYPES: BEGIN OF ty_result,
         lgart TYPE string,
         betrg TYPE string,
         betpe TYPE string,
       END OF ty_result,
       ty_results TYPE STANDARD TABLE OF ty_result WITH EMPTY KEY.
DATA: known_table       TYPE ty_results,
      also_known_table  TYPE ty_results,
      mt_period_results TYPE ty_results.

FIELD-SYMBOLS: <dynamic_table> TYPE STANDARD TABLE,
               <betrg>, <betpe>, <lgart>.

LOOP AT known_table REFERENCE INTO DATA(known_line).

  READ TABLE <dynamic_table> TRANSPORTING NO FIELDS WITH KEY ('LGART') = known_line->*-lgart.

  IF sy-subrc <> 0. CONTINUE. ENDIF.

  DATA(lv_tabix) = sy-tabix.

  LOOP AT <dynamic_table> ASSIGNING FIELD-SYMBOL(<dynamic_line>) FROM lv_tabix.

    UNASSIGN: <betrg>, <betpe>, <lgart>.

    ASSIGN COMPONENT: 'BETPE' OF STRUCTURE <dynamic_line> TO <betpe>,
                      'BETRG' OF STRUCTURE <dynamic_line> TO <betrg>,
                      'LGART' OF STRUCTURE <dynamic_line> TO <lgart>.


    IF <lgart> <> known_line->*-lgart.
      EXIT.
    ENDIF.

    APPEND VALUE ty_result( lgart = <lgart>
                            betrg = <betrg>
                            betpe = <betpe> ) TO mt_period_results.

  ENDLOOP.
ENDLOOP.

当内部表不是动态表时，我可以这样做：

 append lines of value zwta_t_results(
   for known_line in known_table
    for also_known_line  in also_known_table 
      where ( lgart = known_line-lgart )
        ( lgart = known_line-lgart
          betrg = also_known_line-betrg
          betpe = also_known_line-betpe ) to mt_period_results.

所以问题是：动态表是否可以使用FOR迭代器（作为第二种方法）？

Answer 1

我的回答已针对ABAP 7.52进行了检查。不幸的是，当前只能通过在构造表达式（包括“ ASSIGN” table iterations）内使用LET <fs> = writable_expression IN来使用FOR静态变体的子集，其中“ “可写表达式”仅限于表表达式NEW和CAST。因此非常有限，ASSIGN的动态变体没有等效项，因此您只能使用变通办法。

WHERE之后的语法允许使用动态表达式，因此可以输入WHERE ('LGART = KNOWN_LINE-LGART')。但是，如果该循环嵌套在另一个循环中（如您的情况），则可能会非常不利。因此，应定义一个索引，以加快迭代速度。如果要使用二级索引，则条件应为USING KEY ('KEYNAME') WHERE ('LGART = KNOWN_LINE-LGART')。

现在，这是针对您的特殊情况的解决方法：您可以静态定义组件名称，因此一种可能性是使用这些组件名称定义静态结构，并使用CORRESPONDING构造运算符。请注意，我没有对其进行测试，但是出于多种原因，我认为在您的情况下，使用CORRESPONDING的性能要比使用ASSIGN的性能更快。

以下代码应该可以工作。我假设<dynamic_table>后面的内部表具有按LGART（TYPE SORTED TABLE OF ... WITH NON-UNIQUE KEY lgart）排序的主键，因此性能良好：

TYPES: BEGIN OF ty_struc,
         lgart TYPE string,
         betrg TYPE string,
         betpe TYPE string,
       END OF ty_struc.

known_table = VALUE #( ( lgart = 'A' ) ( lgart = 'B' ) ).
also_known_table = VALUE #( ( lgart = 'A' ) ( lgart = 'C' ) ( lgart = 'A' ) ).
ASSIGN also_known_table TO <dynamic_table>.

APPEND LINES OF
    VALUE ty_results(
      FOR known_line IN known_table
        FOR <inner_line> IN <dynamic_table>
          WHERE ('LGART = KNOWN_LINE-LGART')
          LET struc = CORRESPONDING ty_struc( <inner_line> ) IN
          ( lgart = known_line-lgart
            betrg = struc-betrg
            betpe = struc-betpe ) )
    TO mt_period_results.

将FOR与动态内部表一起使用

1 个答案: