我找到了一种使用旋转按钮在范围内循环的方法,使我可以更轻松地打印文档。我想尝试将其与保存PDF宏结合起来,以使其变得更快。
SpinButton更改单元格A1中列出的名称,然后动态更改工作表上的所有数据。 SpinButton的目的是使其更容易在范围内循环。与SavePDF代码相同,我这样做是为了使打印工作表比手动进行更为容易。
SpinButton代码:
Private Sub SpinButton1_SpinDown()
If SpinButton1 = 0 Then
SpinButton1 = Worksheets("Data List").Range("AdvisorNames").Rows.Count
End If
End Sub
Private Sub SpinButton1_SpinUp()
If SpinButton1 = Worksheets("Data List").Range("AdvisorNames").Rows.Count + 1 Then
SpinButton1 = 1
End If
End Sub
保存PDF代码:
Sub SavePDF()
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:="**FILEPATH**" & Range("A1").Value _
, Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas _
:=False, OpenAfterPublish:=False
End Sub
该范围内的名称每个月可能会有所不同,因此我不确定是否可以说明这一点。也许有一个弹出窗口问我要重复几次该动作?
我想找到的是一种将旋转按钮的使用与保存pdf代码结合到一个宏中的方法。旋转按钮将更新单元格A1,然后动态更新工作表的其余部分,然后保存PDF代码将工作表保存到我的桌面。
答案 0 :(得分:0)
尝试类似这样的方法。我认为您根本不需要旋转按钮,因为您已经具有命名范围"AdvisorNames"
中的名称:
Sub SaveAllPDFs()
Dim cl as Range, thisName as String
With ActiveSheet
For Each cl in Worksheets("Data List").Range("AdvisorNames")
thisName = cl.Value
.Range("A1").Value = thisName
.ExportAsFixedFormat Type:=xlTypePDF, Filename:="**FILEPATH**" & thisName _
, Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas _
:=False, OpenAfterPublish:=False
Next
End With
End Sub