Question

在程序中查找编号。一串元音。我被困在“输入字符串：”为什么？即使编译器说一切正常。

程序计算编号一串元音。

;;;;;;;PROGRAM TO CHECK NO. OF VOWELS IN A STRING;;;;;
.model small
.stack 100h
.data
vowels db 'AEIOUaeiou$'
msg1 db 'Enter a string:$'
msg2 db 'The string is:$'
msg3 db 'No of vowels are:$'
string db 50 dup('$')
count db ?
.code
main proc
mov ax, @data
mov ds, ax
mov es, ax
lea dx,msg1
mov ah,09h             ;for displaying enter a string
int 21h
lea di,string
cld
xor bl,bl
input:mov ah,01         ; stuck here, at taking input, why??
cmp al, 13
je endinput
stosb
inc bl
jmp input
endinput:cld
xor bh,bh
lea si,string
vowelornot: mov cx,11
lodsb
lea di,vowels
repne scasb
cmp cx, 00
je stepdown
inc bh
stepdown: dec bl
jnz vowelornot
mov ah,06                ;;;THIS FOR CLEARING SCREEN I GUESS
mov al,0                  ;;;
int 10h
lea dx,msg2
mov ah,09
int 21h
mov dl, 13                  ;;; NEW LINE
mov ah, 2
int 21h
mov dl, 10
mov ah, 2
int 21h
lea dx,string
mov ah, 09
int 21h
mov dl,13                   ;;;NEW LINE
mov ah,2
int 21h
mov dl,10
mov ah,2
int 21h
lea dx, msg3
mov ah,09
int 21h
mov dl,13                  ;;;NEW LINE
mov ah,2
int 21h
mov dl,10
mov ah,2
int 21h
mov count, bh
mov dh, count                   ;;; DH = VOWEL COUNT
mov ah,09
int 21h
mov ah, 4ch                            ;;; EXIT
int 21h
main endp
end

Answer 1

多个错误

input:mov ah,01         ; stuck here, at taking input, why??
cmp al, 13

此处您的代码缺少int 21h指令！

input:
 mov ah,01
 int 21h
 cmp al, 13

 xor bl,bl
input:

 stosb
 inc bl
 jmp input

您正在使用BL来计数输入字符串中的字符数，但是您编写的示例所需的内容远远超过此 byte-size 寄存器的255个最大值。可以给你。这一定会失败！

此外，您设置的缓冲区限制为50个字节。您不可能在那里存储这么长的输入。

lea si,string
vowelornot: mov cx,11
lodsb
lea di,vowels
repne scasb
cmp cx, 00
je stepdown
inc bh
stepdown: dec bl
jnz vowelornot

这太复杂了。只需解释一下ZeroFlag，就根本不用看CX。您无需再用“ $”终止元音文本（使用CX=10）。

 lea si,string
vowelornot:
 lodsb
 mov cx,10
 lea di,vowels
 repne scasb
 jne stepdown
 inc bh        ;Vowel found +1
stepdown:
 dec bl
 jnz vowelornot

mov ah,06                ;;;THIS FOR CLEARING SCREEN I GUESS
mov al,0                  ;;;
int 10h

当然，函数06h可以清除屏幕，但是您需要提供所有必需的参数。 CX中的Upperleftcorner，DX中的Lowerrightcorner和BH中的Displaypage。

mov dx, 184Fh   ;(79,24) If screen is 80x25
xor cx, cx      ;(0,0)
mov bh, 0
mov ax, 0600h
int 10h

lea dx,string
mov ah, 09
int 21h

这将失败，因为您没有在输入的字符串的末尾放置“ $”字符。
如果之后要直接输出CRLF，为什么不将其添加到缓冲区中呢？

 jmp input
endinput:
 mov ax, 0A0Dh  <-- ADD THIS
 stosw          <-- ADD THIS
 mov al, "$"    <-- ADD THIS
 stosb          <-- ADD THIS

 xor bh,bh

您打印 msg2 和 msg3 ，然后打印CRLF。为什么不将其附加在定义中？不再需要单独输出。

msg2 db 'The string is:', 13, 10, '$'
msg3 db 'No of vowels are:', 13, 10, '$'

mov count, bh
mov dh, count                   ;;; DH = VOWEL COUNT
mov ah,09
int 21h

要输出计数并提供一个介于0到9之间的数字，您需要将该数字转换为字符。只需加上48或'0'。
不要使用功能09h。它需要一个地址，并且您显然想使用字符。

mov dl, bh    ;Count of vowels [0,9]
add dl, '0'
mov ah, 02h
int 21h

我被困在“输入字符串：”并且不进行任何输入8086编程

1 个答案:

多个错误