gnuplot动画2D矢量场

Question

我正在尝试使用gnuplot为2D向量设置动画。我想显示一行，即一次显示一个向量。

我的数据结构如下：他们x，y，u，v

2.24448 0.270645    1.00    1.00
3.24448 0.270645    0.500   1.20

我可以通过以下命令创建静态图：

plot "datam.dat" using 1:2:3:4 with vectors filled head lw 3

这是输出：

这是我的问题：我想设置动画并一次显示一行（即）一个矢量，该如何使用GIF在GNU图中完成此操作？

谢谢

Answer 1

动画GIF使用set terminal gif animate创建。检查help gif以获得详细信息。 下面是一个简单的示例（使用gnuplot 5.2测试）。您必须为每个帧绘制一个新图。因此，将您的plot命令放入do for循环中。使用every ::i::i时，您仅绘制第i条线（选中help every）。如果您不知道数据文件的总行数，请执行stats "YourFile.dat"，变量STATS_records会告诉您该数字。

代码：

### animated graph with vectors
reset session

set term gif size 300,300 animate delay 12 loop 0 optimize
set output "AnimateVectors.gif"

# create some dummy data
set angle degrees
N = 60
set samples N
set table $Data
    plot [0:360] '+' u (cos($1)):(sin($1)):(sin($1)):(cos($1)) w table
unset table

set xrange[-2.5:2.5]
set yrange[-2.5:2.5]
do for [i=0:N-1] {
    plot $Data u 1:2:3:4 every ::i::i w vectors lw 2 lc rgb "red" notitle
}
set output
### end of code

结果：

添加：

这将是非动画版本，例如在wxt终端中。

代码：

### non-animated graph with vectors
reset session
set term wxt size 400,400

# create some dummy data
set angle degrees
N = 60
set samples N
set table $Data
    plot [0:360] '+' u (cos($1)):(sin($1)):(sin($1)):(cos($1)) w table
unset table

set xrange[-2.5:2.5]
set yrange[-2.5:2.5]
plot $Data u 1:2:3:4 w vectors lw 1.5 lc rgb "red" notitle
### end of code

结果：

添加2：

您可能是说类似的意思吗？ “半”动画箭头？顺便说一句，正如您所见，箭头在gif和wxt终端中看起来完全不同。

代码：

### "semi"-animated graph with vectors
reset session
set term gif size 300,300 animate delay 12 loop 0 optimize
set output "AnimateVectorsSemi.gif"

# create some dummy data
set angle degrees
N = 60
set samples N
set table $Data
    plot [0:360] '+' u (cos($1)):(sin($1)):(sin($1)):(cos($1)) w table
unset table

set xrange[-2.5:2.5]
set yrange[-2.5:2.5]

do for [i=0:N-1] {
    plot $Data u 1:2:3:4 every ::0::i w vectors lw 1.5 lc rgb "red" notitle
}
set output
### end of code

结果：