Question

我有一个基于arduino的设备（Teensy 3.2），我正在尝试从H3LIS331DL加速度计分线板读取数据。我可以写入加速度计上的控制寄存器，也可以从数据寄存器中读取数据，但是我很难获得稳定，有用的数据。

首先，有用的数据。加速度计芯片的数据表只对数据寄存器说：“ X轴加速度数据。该值表示为2的补码。” SparkFun LIS331库说：“输出的数据是12位数据，左对齐，因此数据的低四位始终为零。”如果数据是每轴12位，我会猜想输出（适当调节）应该是0-4095，零Gs大约是2048，但这与我得到的不匹配。现在，当加速度计静止不动时，X和Y轴显示的是高端和低端（0-19或4063-4095），Z轴显示的是9-80（始终低于2048）任何方向）。

我对数据的期望是错误的，还是我在做一些事情以获取错误的数据？

第二个稳定的数据。该加速度计的低设置为+/- 100G范围。我目前的基准测试是在-1G到+ 1G（整个范围的1％）下进行的，因此我希望输出数据的范围成比例地较小，但是仅从恒定位置开始的输出范围就已经接近整个范围的2％规模。

如何获取更稳定的输出数据？

#include <i2c_t3.h>

#define ACCEL_NEW_PIN    16

#define CTRL_REG1        0x20
#define CTRL_REG2        0x21
#define CTRL_REG3        0x22
#define CTRL_REG4        0x23
#define OUT_X_L          0x28
#define OUT_X_H          0x29
#define OUT_Y_L          0x2A
#define OUT_Y_H          0x2B
#define OUT_Z_L          0x2C
#define OUT_Z_H          0x2D

#define accelAddress     0x19

volatile bool accelNew = true;
int16_t x, y, z;

void setup() {
  delay(1000);
  Serial.begin(115200);
  Serial.println("hello, world!");
  accelSetup();
}

void loop(){
  if(accelNew){
    getAccel(x, y, z);
    Serial.println(x);
    Serial.println(y);
    Serial.println(z);
    accelNew = false;
  }
}

void accelSetup(){
  Wire.begin(I2C_MASTER, 0x00, I2C_PINS_18_19, I2C_PULLUP_EXT, 1800000, I2C_OP_MODE_IMM);
  writeAccel(CTRL_REG1, B00111111); //normal mode, 1000Hz, X, Y and Z enabled
  writeAccel(CTRL_REG2, B00110000); //high pass filter enabled
  writeAccel(CTRL_REG3, B00000010); //Data ready output pin enabled
  writeAccel(CTRL_REG4, B10000000); //Block data update enabled, 100G range
  pinMode(ACCEL_NEW_PIN,INPUT);
  attachInterrupt(digitalPinToInterrupt(ACCEL_NEW_PIN), accelISR, RISING);
}

void accelISR(){
  accelNew = true;
}

void getAccel(int16_t& xAccel, int16_t& yAccel, int16_t& zAccel){
  uint8_t data[6];
  readAccel(OUT_X_L, data, 6);
  xAccel = (data[0] | data[1] << 8) >> 4;
  yAccel = (data[2] | data[3] << 8) >> 4;
  zAccel = (data[4] | data[5] << 8) >> 4;
}

void readAccel(byte address, byte* data, uint8_t bytes)
{
  Wire.beginTransmission(accelAddress);
  Wire.write(address | 0x80);//
  Wire.sendTransmission();
  Wire.sendRequest(accelAddress, bytes);
  while(Wire.available()) *(data++) = Wire.readByte();
}

void writeAccel(byte address, byte data)
{
  Wire.beginTransmission(accelAddress);
  Wire.write(address);
  Wire.write(data);
  Wire.endTransmission();
}

Answer 1

我基本上找到了问题的答案。数据寄存器字节 do 需要按照我的方式进行组合并有一个右移，但是它需要一个 signed 右移，而我的代码等于一个< strong> unsigned 右移。符号位被误认为是值位，并且每当假定数字为负数时，会将结果值发送到范围的顶部。在移位之前将组合的 unsigned bytes 转换为 signed int 可以解决该问题，并使输出数据更有意义。

xAccel = (int16_t)(data[0] | data[1] << 8) >> 4;

好消息是，这三个轴现在都根据方向以相同的线性斜率吐出有意义的数据。

坏消息是，在0G时，每个轴与0的偏移都不同，并且每个轴与平均值之间的方差/抖动仍然约为+/- 18（高于我的期望）。

如何获得可用的加速度计读数

1 个答案: