Question

我对VBA还是很陌生，他在网上找到了一个代码，可以将电子邮件发送给多个收件人，但每个电子邮件只能附加一个文件。我找不到有效的代码，该代码进入特定文件夹并附加存储在该文件夹中的所有PDF文件，并进入另一个文件夹并对下一个电子邮件收件人执行相同的操作。该图显示了我正在处理的工作表的结构。我正在使用Office 365。

Excel Sheet

请帮助。谢谢。

Sub SendMail()

    ActiveWorkbook.RefreshAll

    Dim objOutlook As Object
    Dim objMail As Object
    Dim ws As Worksheet

    Set objOutlook = CreateObject("Outlook.Application")
    Set ws = ActiveSheet

On Error GoTo MyHandler

  For Each cell In ws.Range("A2:A2000")

    Set objMail = objOutlook.CreateItem(0)

        With objMail
            .To = cell.Value
            .Cc = "email@email.com"
            .Subject = cell.Offset(0, 1).Value
            .Body = cell.Offset(0, 2).Value
            .Attachments.Add cell.Offset(0, 3).Value
            .Display
        End With

        Set objMail = Nothing
    Next cell

    Set ws = Nothing
    Set objOutlook = Nothing

MyHandler:
MsgBox "Review email messages"

End Sub

Answer 1

您基本上需要为文件夹中的每个文件重复使用Attachment.Add方法：

Sub SendMail()

ActiveWorkbook.RefreshAll

Dim objOutlook As Object
Dim objMail As Object
Dim ws As Worksheet
Dim StrFile As String, StrPath As String

Set objOutlook = CreateObject("Outlook.Application")
Set ws = ActiveSheet

On Error GoTo MyHandler

For Each cell In ws.Range("A2:A2000")

   Set objMail = objOutlook.CreateItem(0)

    With objMail
        .To = cell.Value
        .Cc = "email@email.com"
        .Subject = cell.Offset(0, 1).Value
        .Body = cell.Offset(0, 2).Value
    End With

        StrPath = "D:\any_folder\" 
        StrFile = Dir(StrPath & "*.*")

        Do While Len(StrFile) > 0
            objMail.Attachments.Add StrPath & StrFile
            StrFile = Dir
        Loop  

    objMail.Display

    Set objMail = Nothing
Next cell

 Set ws = Nothing
 Set objOutlook = Nothing

MyHandler:
  MsgBox "Review email messages"

End Sub

Answer 2

这会做你想要的。

Sub Send_Files()
'Working in Excel 2000-2016
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
    Dim OutApp As Object
    Dim OutMail As Object
    Dim sh As Worksheet
    Dim cell As Range
    Dim FileCell As Range
    Dim rng As Range

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set sh = Sheets("Sheet1")

    Set OutApp = CreateObject("Outlook.Application")

    For Each cell In sh.Columns("B").Cells.SpecialCells(xlCellTypeConstants)

        'Enter the path/file names in the C:Z column in each row
        Set rng = sh.Cells(cell.Row, 1).Range("C1:Z1")

        If cell.Value Like "?*@?*.?*" And _
           Application.WorksheetFunction.CountA(rng) > 0 Then
            Set OutMail = OutApp.CreateItem(0)

            With OutMail
                .to = cell.Value
                .Subject = "Testfile"
                .Body = "Hi " & cell.Offset(0, -1).Value

                For Each FileCell In rng.SpecialCells(xlCellTypeConstants)
                    If Trim(FileCell) <> "" Then
                        If Dir(FileCell.Value) <> "" Then
                            .Attachments.Add FileCell.Value
                        End If
                    End If
                Next FileCell

                .Send  'Or use .Display
            End With

            Set OutMail = Nothing
        End If
    Next cell

    Set OutApp = Nothing
    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

注意：

Make a list in Sheets("Sheet1") with :

In column A : Names of the people
In column B : E-mail addresses
In column C:Z : Filenames like this C:\Data\Book2.xls (don't have to be Excel files)

https://www.rondebruin.nl/win/s1/outlook/amail6.htm

向具有多个附件的多个收件人发送电子邮件

2 个答案: