Question

在这篇旧文章之后，我很想知道如何将标签手动放置在山峰上。

具有以下内容：！（http://publications.iodp.org/proceedings/324/203/images/03_F04.jpg）

第1版

我已经修改了这两个代码以使其适应我想要的内容，但是出现错误。

我的代码如下：

set terminal postscript enhanced color"Times-Roman" 20
set xlabel "2{/Symbol Q} (°)"
set ylabel "Intensity (a.u.)"
set xrange [10:90]
set key off
set decimalsign
set output "UHTC-XRD.eps"
set palette defined (1 "red", 2 "green", 3 "blue")
unset colorbox
array Materials[3] = ["ZrB_2", "SiC", "C"]
Gap = 150
Length = 500
plot  "XRD_UHTC_data.txt" using 2:1 with lines lc rgb "blue" title "lines", "peaksUHTC.txt" for [i=1:3] '' u (i==$3?$2:NaN):($1+Gap+Length+Gap):3 w p pt 7 palette title Materials[i]

对于以下光谱数据（我只会指出几行，即+4000）：

我得到这个数字：

第一个问题，如何删除y轴值？关于峰的标记，我以以下文件为例

# PosY PeakX  Category
10697 41.77 1
6383 32.73 1
259 35.81 2
101 16.27 3

但是主文件中出现此错误：

“ gnuXRD_UHTC.txt”第26行：意外的或无法识别的令牌

我看不出有什么问题。

Answer 1

一个建议（需要gnuplot> = 5.2）：您需要有一个数据文件/数据块，其中包含峰位置，峰强度以及材料类别（例如，数字）。由于我没有XRD数据，因此我只是用脉冲来绘制峰（用您的XRD数据代替这条线）。然后，将with vectors用作峰上方的短线，并将with points用作符号。一种方法是使用调色板来获得作为材质类功能的颜色。为了正确显示图例的颜色，在遍历材质时需要跳过某些曲线（表达式：...(i==$3?$1:NaN)...）也许，还有其他（更简便的方法）可以达到相同的结果。

代码：

### labeling of peaks
reset session

$PeakData <<EOD
# PosX PeakY  Category
9.56   998.8  2
11.2  1215.9  3
26.9  1315.0  1
34.6  4927.5  1
36.6  1023.1  1
42.1  1262.3  1
46.0  1609.7  4
50.5  1404.1  1
55.4  1393.8  1
55.5  1686.6  2
56.9  1545.7  3
66.4   581.4  1
67.8   722.5  3
72.0   679.6  2
72.9   571.2  3
74.9   419.5  3
76.9   582.4  4
78.3   484.9  1
EOD

Gap = 150
Length = 500
set palette defined (1 "red", 2 "green", 3 "blue", 4 "orange")
unset colorbox
array Materials[4] = ["Material 1", "Material 2", "Material 3", "Material 4"]

plot $PeakData u 1:2 with impulses lw 2 lc rgb "violet" notitle, \
     $PeakData u 1:($2+Gap):(0):(Length) with vectors nohead notitle, \
     for [i=1:4] '' u (i==$3?$1:NaN):($2+Gap+Length+Gap):3 w p pt 7 palette title Materials[i]
### end of code

结果：

XRD光谱峰中值的标记

1 个答案: