Question

在MQL4中，我可以使用以下函数从二维数组中打印值：

string Arr2ToString(double& arr[][], string dlm = ",", int digits = 2) {
  string res = "";
  int i, j;
  for (i = 0; i < ArrayRange(arr, 0); i++) {
    res += "[";
    for (j = 0; j < ArrayRange(arr, 1); j++) {
      res += StringFormat("%g%s", NormalizeDouble(arr[i][j], digits), dlm);
    }
    res = StringSubstr(res, 0, StringLen(res) - StringLen(dlm));
    res += "]" + dlm;
  }
  res = StringSubstr(res, 0, StringLen(res) - StringLen(dlm));
  return res;
}

但是，在MQL5（版本5.00，内部版本1966）中，上述功能不再起作用，并且出现以下错误：

'['-无效的索引值Array.mqh

在通过arr[][]的第一行中

。

我已经检查过，MQL5不再允许传递没有尺寸大小的数组。

将多维数组传递给函数时，应指定尺寸大小（第一个尺寸除外）：
double var[][3][3];
void Func(double &arg[][3][3]){    // ... }

来源：MQL5 PROGRAMMING BASICS: ARRAYS。

这没有道理。

假设我不知道数组的大小（因为我想针对多种数组类型重复使用此函数，并且为每种大小定义数十个单独的函数是荒谬的），现在如何打印值来自存储双精度值的多维数组（例如二维数组）？

Answer 1

我知道这并不理想，但是我们可以使用ArrayPrint()打印数组。 Refer here for the documentation

void  ArrayPrint( 
   const void&   array[],             // printed array 
   uint          digits=_Digits,      // number of decimal places 
   const string  separator=NULL,      // separator of the structure field values 
   ulong         start=0,             // first printed element index 
   ulong         count=WHOLE_ARRAY,   // number of printed elements 
   ulong         flags=ARRAYPRINT_HEADER|ARRAYPRINT_INDEX|ARRAYPRINT_LIMIT|ARRAYPRINT_ALIGN     
   );

这是将多维数组传递给函数的另一种方法，这也不理想，但可以正常工作。

//+------------------------------------------------------------------+
//| Struct that is used to hold multi-dimentional array              |
//+------------------------------------------------------------------+
template<typename T>
struct MultiDimentionalArray
  {
   T                 index2[];      
  };
//+------------------------------------------------------------------+
//| Array print function that accepts MultiDimentionalArray struct   |
//+------------------------------------------------------------------+
string Arr2ToString(MultiDimentionalArray<double> &arr[],string dlm=",",int digits=2)
  {
   string res="";
   int i,j;
   for(i=0; i<ArraySize(arr); i++)
     {
      res+="[";
      for(j=0; j<ArraySize(arr[i].index2); j++)
        {
         res+=StringFormat("%g%s",NormalizeDouble(arr[i].index2[j],digits),dlm);
        }
      res = StringSubstr(res,0,StringLen(res) - StringLen(dlm));
      res+= "]" + dlm;
     }
   res=StringSubstr(res,0,StringLen(res)-StringLen(dlm));
   return res;
  }

这是示例执行

void OnStart()
  {
//--- Declaring an array
   MultiDimentionalArray<double> arr[];

//--- Adding values to the array
   for(int i=0;i<10;i++)
     {
      //--- Resizing the array - 1st dimention
      if(ArraySize(arr)<=i) ArrayResize(arr,ArraySize(arr)+1);

      for(int j=0;j<10;j++)
        {
         //--- Resizing the array - 2nd dimention
         if(ArraySize(arr[i].index2)<=j) ArrayResize(arr[i].index2,ArraySize(arr[i].index2)+1);
         arr[i].index2[j]=i*j;
        }
     }

//--- Getting the result as string
   string arrResult=Arr2ToString(arr);
//--- Printing the result string
   Print(arrResult);
  }

这是执行上述代码后在“专家”标签中得到的结果

2019.06.11 16:25:47.078 Arrays (EURUSD,H1)  [0,0,0,0,0,0,0,0,0,0],[0,1,2,3,4,5,6,7,8,9],[0,2,4,6,8,10,12,14,16,18],[0,3,6,9,12,15,18,21,24,27],[0,4,8,12,16,20,24,28,32,36],[0,5,10,15,20,25,30,35,40,45],[0,6,12,18,24,30,36,42,48,54],[0,7,14,21,28,35,42,49,56,63],[0,8,16,24,32,40,48,56,64,72],[0,9,18

如何从MQL5中的多维数组打印值？

1 个答案: