Question

我正在Arduino（Mega2560开发板，Arduino 1.8.9，JSN-SR04T-2.0超声波传感器）中创建一个测距系统。由于传感器不是很稳定，因此我希望每500毫秒对15个测量值或测量值取平均值，以先到者为准。这些值存储在一个15整数长的数组中，并且有一个计数器告诉您进行了多少次测量。问题是，当完成15次测量并且我想求平均值（不包括在代码中，仅包含if（...）部分）时，计数器从14跃升至非常高的值而没有任何解释，并从那里继续计数。另外，如果我设置了非常高的循环时间（例如1800毫秒），有时它会返回0而不输入if结构（cntr = 0行所在的位置）。

我将代码精简到最少，以查找可能导致问题的原因。似乎当我使用存储在“ valueArrayUS”中的值时，它不起作用。如果我将其注释掉，它将起作用。我尝试了两种使用该值的方法，但都弄乱了。

最小的可运行代码为：

int trigPin = 8;    // Trigger
int echoPin = 9;    // Echo
int cntr=0; //how many measurements
long startTime=0; //start time of cycle
int valueArrayUS[15]; //max 15 values per cycle
int valueArrayUScp[15]; //copy of valueArrayUS
int sumUS=0;
long duration, cm;
int i=0, j=0;

void setup() {
  Serial.begin (9600);
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);

  for (i=0; i<15; i++) {
    valueArrayUS[i]=0; //default state
    valueArrayUScp[i]=valueArrayUS[i];
  }
  startTime=millis(); //time counter start
}

void loop() {

  //ultrasonic measurement
  digitalWrite(trigPin, LOW);
  delayMicroseconds(50);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(20);
  digitalWrite(trigPin, LOW);

  duration = pulseIn(echoPin, HIGH, 38000); //if no object is detected -> 38 ms long pulse from sensor -> 38 ms timeout
  cm = (duration/2) / 29.1;     // Divide by 29.1 or multiply by 0.0343
  valueArrayUS[cntr]=cm;

  Serial.print("cntr:  ");
  Serial.print(cntr);
  Serial.println();

  if ((millis()-startTime>500) || (cntr==15)) { //cycle is ended or buffer full

    Serial.print("enters the cycle, cycle time: ");
    Serial.println();
    Serial.print(millis()-startTime);
    Serial.print(" ms ");
    Serial.println();
    Serial.print("cntr at cycle start: ");
    Serial.print(cntr);
    Serial.println();

    //averaging would be here
    for (j=0; j<15; j++) { 
      valueArrayUScp[j]=valueArrayUS[j];  //THIS IS WHERE IT GOES WRONG
      //sumUS=sumUS+valueArrayUS[j]; //THIS IS WHERE IT GOES WRONG
    }

   for (i=0; i<15; i++) {
    valueArrayUS[i]=0; //default state
    }
    cntr=0; 
    startTime=millis();
    }
  else {
    cntr=cntr+1;
    Serial.print("cntr++    ");
    Serial.println();
  }
}

您可以看到注释的行及其上方的行，都破坏了代码。如果两者都被注释掉，它将按预期工作。如果其中任何一个存在，则结果如下：

15:51:33.848 -> cntr:  11
15:51:33.894 -> cntr++    
15:51:33.894 -> cntr:  12
15:51:33.894 -> cntr++    
15:51:33.894 -> cntr:  13
15:51:33.942 -> cntr++  
15:51:33.942 -> cntr:  14
15:51:33.942 -> cntr++    
15:51:33.942 -> cntr:  117
15:51:33.989 -> cntr++   
15:51:33.989 -> cntr:  118
15:51:33.989 -> cntr++    
15:51:34.036 -> cntr:  119
15:51:34.036 -> cntr++    
15:51:34.036 -> cntr:  120
15:51:34.036 -> cntr++    
15:51:34.083 -> cntr:  121
15:51:34.083 -> cntr++    
15:51:34.083 -> cntr:  122
15:51:34.083 -> cntr++    
15:51:34.129 -> cntr:  123
15:51:34.129 -> cntr++    
15:51:34.129 -> cntr:  124
15:51:34.129 -> cntr++    
15:51:34.176 -> cntr:  125
15:51:34.176 -> cntr++    
15:51:34.176 -> cntr:  126
15:51:34.223 -> enters the cycle, cycle time: 
15:51:34.223 -> 557 ms 
15:51:34.270 -> cntr at cycle start: 126
15:51:34.270 -> cntr:  0
15:51:34.270 -> cntr++    
15:51:34.318 -> cntr:  1

应该是：

15:57:33.132 -> cntr:  14
15:57:33.132 -> cntr++    
15:57:33.132 -> cntr:  15
15:57:33.132 -> enters the cycle, cycle time: 
15:57:33.179 -> 392 ms 
15:57:33.179 -> cntr at cycle start: 15
15:57:33.226 -> cntr:  0
15:57:33.226 -> cntr++    
15:57:33.226 -> cntr:  1

是什么原因造成的？

Answer 1

您的循环会这样做：

{
  valueArrayUS[cntr]=cm;
    //...
  if ((millis()-startTime>500) || (cntr==15)) { //cycle is ended or buffer full
    //...
  else {
    cntr=cntr+1;
  }
}

在删除其余代码的情况下，更容易看出自己是

使用cntr
测试cntr是否为15（即超过数组末尾）
更新cntr

在loop()的前15次中这不是问题，但是在该函数结束后的第15次cntr变为15时，在下一次遍历该函数时，您最终会这样做：

valueArrayUS[15]=cm;

这意味着您正在写超出数组末尾的位置，并且看来valueArrayUS之后的内存中的下一个对象必须是cntr，因为您显然是在写该值。 / p>

这是问题的核心，但是一旦发生这种情况，您就将遭受重创，因为现在cntr的值可能会大于15，因此您的cntr==15情况是不正确的，现在loop将写传感器值到valueArrayUS的末尾。这将有效地消耗您的全部内存，并且在给定运行中确切覆盖哪些内存将取决于传感器恰好正在读取什么。

要解决此问题，您需要重新安排步骤：

检查cntr是否在范围内
如果不是，请进行计算并重置cntr
如果cntr有界，那么您可以读取传感器，存储值并更新cntr

此外，还应进行防御性编码：

将您的条件从cntr == 15更改为cntr > 14或cntr >= 15
在本地声明其他循环变量i和j，例如：for (int i...

Arduino循环中的怪异行为

1 个答案: