Question

有人在gnuplot中有饼图示例代码吗？我找不到一个简单的图形，其周围的文本以及其中带有％符号（可以轻松显示每个圆环的多少）的示例。

一些示例数据：

Management frames   4596
Control frames  70173
Data frames 40347
TCP packets 36864
HTTP packets    525
ICMP packets    47
Total frames    115116

Answer 1

以下代码与我上面引用的链接有些不同。

不是在单独的列表中使用预定义的颜色序列或数字代码，而是通过gnuplot中预定义颜色的名称在项目/编号旁边的数据块（或数据文件）中给出部分的颜色（另请参见{{ 3}}）
根据标签相对于left的位置，标签对齐right或0。 @Labels只是在几行之前插入为Labels定义的文本。这应该使绘图命令更短一些，并希望减少混乱。
您可以通过饼图的PieStart选择起始角度，通过PieDirection选择“旋转”方向
您可以为细分和标签添加单独的x，y偏移量

如您所见，原始数据中不需要总和。总金额将自动计算。

我希望您可以根据需要修改此代码。

关于标签位置的一些说明：根据标签的位置是在圆的右侧（LabelPosX>=0还是左侧（LabelPosX<0）的一半，对齐方式将分别为left和right。使用绘图样式with labels，您可以指定标签的对齐方式，但是显然不能将其指定为变量，因为gnuplot在with之后的表达式仅在plot命令的末尾计算一次，而不是在每个数据点期间计算一次。这就是为什么它需要两个命令分别绘制左对齐和右对齐标签的原因。如果有更简单的方法，请告诉我。

代码：

### pie-chart with labels with gnuplot
reset session
set size square
set angle degree
unset colorbox
set border 0
unset tics
unset key 

$Data <<EOD
# item  value   color   SegmentOffsetX  SegmentOffsetY  LabelOffsetX    LabelOffsetY
"Abc zyx"   85843   red 0   0   0   0
"Def wvu"   44000   green   0   -0.2    0   -0.2
"Ghi tsr"   25399   blue    0   0   0   0
"Jkl qpo"   18451   magenta 0   0   0   0
"Mno nml"   12344   yellow  0   0   0   0
"Pqr kji"   11999   cyan    0   0   0   0
"Stu hgf"   9000    orange  0   0   0   0
"Vwx edc"   8500    olive   0   0   0   0
"Yz ba" 4711    violet      0   0   0.05    0.05
EOD

# define a palette from colornames of the datafile/datablock in column 3
MyPalette = '('
set table $Dummy
    plot $Data u (MyPalette = MyPalette.sprintf('%d "%s", ',$0+1,strcol(3)),0) with table
unset table
MyPalette = MyPalette[:strlen(MyPalette)-2].')'
set palette defined @MyPalette

stats $Data u 2 nooutput    # get total sum from column 2
TotalSum = STATS_sum

set xrange[-1.5:1.5]
set yrange[-1.5:1.5]

Radius = 1.0
RadiusLabels = 1.05
PieStart = 90          # 0 = 3 o'clock, 90 = 12 o'clock
PieDirection = -1      # -1 clockwise, 1 counterclockwise
LabelPosX(n,dx) = RadiusLabels*cos(PieDirection*(2*Sum+n)/TotalSum*180.+PieStart)+dx
LabelPosY(n,dy) = RadiusLabels*sin(PieDirection*(2*Sum+n)/TotalSum*180.+PieStart)+dy

Sum = PieDirection==1 ? 0 : TotalSum
Angle1(n) = (PieDirection==1 ? Sum/TotalSum*360 : (Sum=Sum-n, Sum/TotalSum*360)) + PieStart
Angle2(n) = (Sum=Sum+n, Sum/TotalSum*360) + (Sum=Sum-n, PieStart)

Labels = 'LabelPosX($2,$6):NaN): (LabelPosY($2,$7)): \
    (Sum=Sum+$2,sprintf("%s %.1f%%", strcol(1), $2/TotalSum*100)) with labels font ",12"'

plot $Data u (0+$4):(0+$5):(Radius):(Angle1($2)):(Angle2($2)):($0) \
    with circles fs solid 1.0 lc palette notitle,\
    '' u (LabelPosX($2,$4)>=0 ? @Labels left, \
    '' u (LabelPosX($2,$4)<0  ? @Labels right
### end of code

结果：

https://stackoverflow.com/a/55736522/7295599

饼图gnuplot

1 个答案: