Question

有人可能已经问过这个问题，但是还没有找到，所以问题就解决了：

我想解析组件的tkSet属性（在我们的例子中为Panel1），但是我不知道如何正确地做到这一点。我可以使用rContext.FindType（）找到该集合的基本枚举类型，但是我几乎可以肯定，有一些更优雅/更简单的方法可以做到这一点。从那时起，我完全迷路了。我应该仔细研究该枚举类型的值，并对照组件的当前属性值检查每个值。

procedure TForm12.GetProperties2;
var
  rContext: TRttiContext;
  rType: TRttiType;
  rProp: TRttiProperty;
begin
  rType := rContext.GetType(Panel1.ClassType);

  for rProp in rType.GetProperties do
  begin
    if (rProp.Visibility in [mvPublished]) and (rProp.PropertyType.TypeKind in [tkSet]) and (rProp.Name = 'Anchors') then
    begin
      Memo1.Lines.Add('Name: ' + rProp.Name);
      Memo1.Lines.Add('PropertyType: ' + rProp.PropertyType.ToString);
      Memo1.Lines.Add('Value: ' + rProp.GetValue(Panel1).ToString);
      Memo1.Lines.Add('QualifiedName: ' + rProp.PropertyType.QualifiedName);
      Memo1.Lines.Add('ElementType: ' + rContext.FindType(rProp.PropertyType.QualifiedName).AsSet.ElementType.ToString);
      // here comes the desired results
      Memo1.Lines.Add('Possible values:');
      Memo1.Lines.Add(' 0 > akLeft');
      Memo1.Lines.Add(' 1 > akTop');
      Memo1.Lines.Add(' 2 > akRight');
      Memo1.Lines.Add(' 3 > akBottom');
      Memo1.Lines.Add('Present values:');
      Memo1.Lines.Add(' 0 > akLeft');
      Memo1.Lines.Add(' 1 > akTop');
      Memo1.Lines.Add('');
    end;
  end;
end;

另一个可能的问题是没有基本枚举类型的set属性，例如，如果您查看TPanel.StyleElements属性，则可以看到TStyleElements的声明如下：

TStyleElements = set of (seFont, seClient, seBorder);

在这种情况下，ElementType不起作用。

所以问题是如何使用RTTI上下文解析tkSet类型属性以获得所需的结果？

Answer 1

使用基本的TypInfo，这非常容易。

procedure PrintSet(const v: TValue); // v contains a value from a set type
var
  enumType: PTypeInfo;
  enumData: PTypeData;
  buffer: set of Byte; // biggest possible set type
  i: Integer;
begin
  buffer := [];
  v.ExtractRawData(@buffer);
  enumType := v.TypeInfo.TypeData.CompType^;
  enumData := enumType.TypeData;
  for i := enumData.MinValue to enumData.MaxValue do
    Writeln(GetEnumName(enumType, i) + ' = ' + (i in buffer).ToString(TUseBoolStrs.True));
end;

set of Byte是可能的最大集合类型，因此我们可以将其用作所有内容都适合的缓冲区，然后使用TValue.ExtractRawData方法向其中写入与实际集合类型一样多的数据。通过将其他所有内容设置为空，可以将其他所有内容清零。

然后，我们可以使用枚举类型的类型数据来获取最小值和最大值。由于非连续的枚举类型没有typeinfo，因此我们不需要照顾它，实际上只处理那些与经典位掩码二进制兼容的类型。

使用RTTI从tkSet类型获取可能的值和当前值

1 个答案: