Question

我想为拉链编写一个函数，以删除节点的所有同级兄弟，同时保留在同一位置。

(defn remove-all-rights-1 [loc]
  (if (zip/right loc) 
    (recur (zip/remove (zip/right loc)))
    loc))

这里的问题是remove返回DFS中当前节点之前的位置。

因此，下面的示例...

(-> (clojure.zip/vector-zip [1 [[2] 3]])
    (zip/down)
    (zip/right)
    (zip/down)
    (remove-all-rights-1)
    (zip/replace :x)
    (zip/root))

...给出[1 [[:x]]]而不是[1 [:x]]，因为zip/remove跳到了底部，而不是仅仅返回了左边。

如何在不更改树中位置的情况下删除合适的兄弟姐妹？？预先感谢！

Answer 1

(letfn [(kill-right [loc]
            (let [lost   (zip/rights loc)
                  parent (-> loc zip/up zip/node)
                  node   (into (empty parent) (take (- (count parent) (count lost)) parent))]
                (-> loc
                    zip/up
                    (zip/replace node)
                    zip/down
                    zip/rightmost)))]
    (-> (clojure.zip/vector-zip [1 [[2] 3]])
        zip/down
        zip/right
        zip/down
        kill-right
        (zip/replace :x)
        zip/root))

Answer 2

概括akond's answer提供了以下解决方案：

(defn remove-all-rights
  "Removes all right siblings. Stays at original location."
  [loc]
  (let [parent-loc (zip/up loc)
        |lefts| (inc (count (zip/lefts loc)))]
    (->> (zip/make-node loc (zip/node parent-loc) (take |lefts| (zip/children parent-loc)))
         (zip/replace parent-loc)
         (zip/down)
         (zip/rightmost))))

主要思想是构造一个父节点的副本，其中子级集合不包含正确的同级。

Answer 3

这可以通过Tupelo Forest库轻松完成：

(dotest
  (with-forest (new-forest)
    (let [edn-orig          [1 [[2] 3]]
          root-hid          (add-tree (edn->tree edn-orig))
          hid               (find-hid root-hid [::tf/list ::tf/list])
          subtree-edn-orig  (-> hid hid->tree tree->edn)
          >>                (kids-update hid butlast)
          subtree-edn-final (-> hid hid->tree tree->edn)
          edn-final         (-> root-hid hid->tree tree->edn)]

      (is= subtree-edn-orig      [[2] 3])
      (is= subtree-edn-final     [[2]])
      (is= edn-final          [1 [[2]]]  ))))

创建的树在第一和第二级具有:tag值为:tupelo.forest/list的节点：

  (is= (hid->bush root-hid)
    [{:tag :tupelo.forest/list, :tupelo.forest/index nil}
     [#:tupelo.forest{:value 1, :index 0}]
     [{:tag :tupelo.forest/list, :tupelo.forest/index 1}
      [{:tag :tupelo.forest/list, :tupelo.forest/index 0}
       [#:tupelo.forest{:value 2, :index 0}]]]] )

HID是指向树节点的指针，因此root-hid指向树的根节点，hid指向子树[[2] 3]。删除最右边的节点3之后，hid指向子树[[2]]。

对于子节点（kids），我们使用butlast函数删除最右边的节点，然后将数据从林/树格式转换回EDN。

请参见the README here和API docs here。还有许多live code examples here。另请参见Clojure Conj video。

Clojure拉链可去除所有兄弟姐妹

3 个答案: