Question

我正在用clojure数据结构写一棵树（业务流程决策树）。

(require clojure.zip :as z)

(z/vector-zip 
    [ :billed?  
        [:yes  
            [:check-bank-account] 
            [:check-cash] ] 
        [:send-out-email] ])

当代码在第一个节点上移动时，它将读取关键字并执行某些操作，结果将为True或False，然后我希望它进入left（True）或right （错误）节点。

当我的代码从根节点开始，并调用与:billed?关联的某个函数时，它返回一个True，clojure如何进入:yes节点或:send-out-email节点？我以为只有z/down，而left或right仅用于同胞而不是孩子的指导。

非常感谢您抽出宝贵的时间，感谢您的想法

Answer 1

束缚多个拉链运动。

这是一个例子：

(require '[clojure.zip :as z])

(def zipper (z/vector-zip
              [:billed?
               [:yes
                [:check-bank-account]
                [:check-cash]]
               [:send-out-email]]))

(println (-> zipper z/down z/right z/down z/node))
(println (-> zipper z/down z/right z/down z/right z/down z/node))

Answer 2

拉链会在跟踪当前位置的同时遍历数据结构。要到达不同的节点，必须对同一拉链应用一系列移动。创建拉链后，您的位置就在树的正上方：

(z/node tree)
=> [:billed? [:yes [:check-bank-account] [:check-cash]] [:send-out-email]]

因此，您可以使用z/down进入树，并使用z/node从拉链的位置获取当前节点：

(-> tree
    z/down
    z/node)
=> :billed?

如果您要将树从顶部移到某个节点，则可能只需要z/down和z/right，因为下降到子向量会将您放置在最左边的子节点上。如果将向量放在一条平面上，然后想象z/right只是将光标移到下一个元素，然后z/down将光标移到 inside a，则更容易想象这向量。

(-> tree
    z/down
    z/right
    z/node)
=> [:yes [:check-bank-account] [:check-cash]]

(-> tree
    z/down
    z/right
    z/right
    z/node)
=> [:send-out-email]

这是一个示例，您可以通过根据事实图评估密钥来走这棵树：

(def tree
  (z/vector-zip
    [:billed?
     [:wire-funds?
      [:check-bank-account]
      [:check-cash]]
     [:send-out-email]]))

(defn facts->action [facts]
  (loop [curr (z/down tree)]
    (let [node (z/node curr)]
      (if-let [fact (find facts node)]
        (if (val fact)
          (recur (-> curr z/right z/down)) ;; descend "left"
          (recur (-> curr z/right z/right z/down))) ;; descend "right"
        node))))

(facts->action {:billed? false})
=> :send-out-email
(facts->action {:billed? true :wire-funds? true})
=> :check-bank-account
(facts->action {:billed? true :wire-funds? false})
=> :check-cash

如何在Clojure中将拉链移动到左/右节点？

2 个答案: