Question

我必须从txt文件中找出最大的数字。数字例如：

9 8 7 6 5

有人告诉我，它应该可以，但是没有，而且我不知道如何使用文件bcs。

program file;
uses crt;
var i,count,help:integer;

numb:array [1..9] of integer;
f:text;

begin
clrscr;

 assign(f,'file1.txt');
 reset(f);

   readln(f,count);

   for i:=1 to count do

    readln(f,numb[i]);

 close(f);

 for i:=2 to count do
  begin

   if (numb[i-1] < numb[i]) then

     help:=numb[i-1];

     numb[i-1]:=numb[i];

     numb[i]:=help;

  end;  

 for i:=1 to count do
  begin

   write(numb[i]);
  end;

readln;
end.

Answer 1

提供的代码中有一些错误：

程序名称为文件。程序名称不能是关键字；
您从文件中读取了变量count，但是在文件中找不到实际值，所以count=0。因此，永远不会执行从文件中读取数据的for循环。您可以从文件或键盘中读取它（在下面的解决方案中，我选择了第二个选项）；
从文件中读取时，您使用readln。 readln在读取数据后将光标移至下一行。这意味着只有第一个数字9存储在numb中。将readln替换为read;
在第二个for循环中，您说if ... then。如果要执行所有三个指令（并且我认为您要执行，因为这是交换值），请将它们放在begin和end之间。否则，如果条件为真，则仅执行第一条指令，否则始终执行其他指令；
确定最大值的方法是过大的。最好使用变量max，该变量最初获取数组中第一个元素的值，然后循环其余值以查看值是否大于max。

最终代码如下：

    program file1;
    uses crt;
    var i,count,help, max:integer;

    numb:array [1..9] of integer;
    f:text;

    begin
     clrscr;
     assign(f,'file1.txt');
     reset(f);  
     writeln('Please input a number for count :');      
     readln(count);  
     for i:=1 to count do  
        read(f,numb[i]);
     close(f);
     max:=numb[1];
     for i:=2 to count do
       if numb[i]>max then
        max:=numb[i];
     write('The result is: ',max); 
    readln;
    end.

Answer 2

如果您只想知道最高编号，则可以在读取文件中的编号时使用最高运行编号。

作为用户，您不必知道文件中有多少个数字。该程序应该确定。

我写了一个小的测试文件，名为 file1.txt ：

9 8 7 6 3 11 17
32 11 13 19 64 11 19 22
38 6 21 0 37

我只读取数字，并将它们与Max进行比较。这就是您所需要的。

无需将数据读入数组和
无需（尝试）对数据进行排序。您只想要最高的号码，对吗？
用户也无需知道或在文本文件中输入数字的数量。

program ReadMaxNumber;

uses
  Crt;

var
  Max, Num: Integer;
  F: Text;

begin
  ClrScr;
  Assign(F, 'file1.txt');
  Reset(F);

  Max := -1;
  while not Eof(F) do
  begin
    Read(F, Num);
    if Num > Max then
      Max := Num;
  end;

  Close(F);
  Writeln('Maximum = ', Max);
  Readln;
end.

运行此命令时，输出符合预期：

Maximum = 64

如何从txt文件中找到最大的数字？

2 个答案: