Question

我试图让用户输入书名，然后测试书是否存在于图书馆中。如果不是，程序应要求他输入书籍详细信息。但是该程序将所有输入视为一本新书。我比较这两个值是错误的还是我的阅读热线？

到目前为止的代码：

(deftemplate book (slot name) (slot author) (slot code))

(deffacts current-lib
  (book (name "Alice in Wonderland") (author Lewis-Carroll) (code CAR))
  (book (name "The Bourne Supremacy") (author Robert-Ludlum) (code LUD)))

(defrule readnew "inputs potential new book details"
=>


(printout t "Enter the name of the book:")
  (bind ?b_name (readline))
  (assert (potential ?b_name)))

(defrule add-book "determine if book already exists otherwise add"
  ?out <- (potential ?newname)
  (and (potential ?newname)
       (not (book (name ?b_name&?newname) (author $?))))
=>
  (printout t "Book is new, please enter the author's name:" crlf)
  (bind ?auth (readline))
  (printout t "Please enter a three letter code for the book:" crlf)
  (bind ?coode (read))
  (assert (book (name ?newname) (author ?auth) (code ?coode)))
  (retract ?out))

Answer 1

您提供了代码，但没有提供运行代码的步骤，因此我不得不猜测导致问题的原因。最简单的解释是，您没有发出 reset 命令来断定 current-lib 事实中的事实。

我对您的代码进行了一些更改。在您的当前库内容中，作者姓名应为字符串，因为您在 add-book 规则中使用 readline 来获取姓名。 添加书规则的条件下也有不必要的代码。

         CLIPS (6.31 2/3/18)
CLIPS> 
(deftemplate book 
   (slot name)
   (slot author) (slot code))
CLIPS> 
(deffacts current-lib
   (book (name "Alice in Wonderland") (author "Lewis Carroll") (code CAR))
   (book (name "The Bourne Supremacy") (author "Robert Ludlum") (code LUD)))
CLIPS> 
(defrule readnew
   =>
   (printout t "Enter the name of the book:" crlf)
   (bind ?b_name (readline))
   (assert (potential ?b_name)))
CLIPS> 
(defrule add-book
  ?out <- (potential ?newname)
  (not (book (name ?newname)))
  =>
  (printout t "Book is new, please enter the author's name:" crlf)
  (bind ?auth (readline))
  (printout t "Please enter a three letter code for the book:" crlf)
  (bind ?coode (read))
  (assert (book (name ?newname) (author ?auth) (code ?coode)))
  (retract ?out))
CLIPS>

现在，如果您添加一本不存在的书，则会要求您提供其他信息。

CLIPS> (reset)
CLIPS> (run)
Enter the name of the book:
Ringworld
Book is new, please enter the author's name:
Larry Niven
Please enter a three letter code for the book:
RNG
CLIPS>

如果您尝试添加不存在的书，则添加书规则将不会执行。

CLIPS> (reset)
CLIPS> (run)
Enter the name of the book:
Alice in Wonderland
CLIPS>

将一个值与另一个值进行比较以测试CLIPS中是否存在文件

1 个答案: