在GLSL着色器中计算点投影

Question

我需要在着色器（OpenGL ES 2）中计算点在特定线段上的投影。
这是我测试算法的方法：
我用点A（0，0.5），B（1，-0.5），C（-1，-0.5）绘制简单三角形。
我计算线段AC上每个点的投影。
在蓝色的线段AC的中间绘制带有投影的点。其余点为绿色。
我希望得到一个绿色三角形，其中蓝色线垂直于AC侧。但是蓝线不垂直于交流电。
我在画布上用绘图检查代码中的投影公式，并得到了预期的结果。
我怎么了

着色器的结果：

顶点着色器：

uniform mat4 matrix;
attribute vec4 position;
varying vec4 vPosition;

void main()
{
    vPosition = matrix * position;
    gl_Position = matrix * position;
}

片段着色器：

precision mediump float;

varying vec4 vPosition;

void main()
{

    vec2 P = vPosition.xy;
    vec2 A = vec2(0.0, 0.5);
    vec2 B = vec2(-1.0, -0.5);
    vec2 AP = P - A;
    vec2 AB = B - A;
    vec2 projection = A + dot(AP, AB) / dot(AB, AB) * AB;

    if(projection.x > -0.51 && projection.x < -0.49 && projection.y > -0.01 && projection.y < 0.01) {
        gl_FragColor = vec4(0.0, 0.0, 1.0, 1.0);
    } else {
        gl_FragColor = vec4(0.0, 1.0, 0.0, 1.0);
    }
}

Answer 1

您没有考虑窗口的矩形形状。将范围为[-1，1]的规范化设备坐标映射到视口矩形（请参见glViewport）时，三角形将被拉伸。这导致无法保持90度角。

向片段着色器添加uniform variable，其中包含视口的宽度和高度：

uniform vec2 u_resolution;

计算纵横比：

float aspect = u_resolution.x / u_resolution.y;

当然，您也可以通过常量值来初始化变量float aspect。
例如float aspect = 16.0/9.0;

根据长宽比校正点A，B和P的坐标：

vec2 P = vPosition.xy;
vec2 A = vec2(0.0, 0.5);
vec2 B = vec2(-1.0, -0.5);

A.x *= aspect;
B.x *= aspect;
P.x *= aspect;

并在评估结果projection时考虑纵横比：

vec2 projection = A + dot(AP, AB) / dot(AB, AB) * AB;
projection.x /= aspect;

最终的片段着色器可能看起来像这样：

precision mediump float;

varying vec4 vPosition;

uniform vec2 u_resolution;

void main()
{
    float aspect = u_resolution.x / u_resolution.y;
    vec2  as = vec2(aspect, 1.0);

    vec2 P = as * vPosition.xy;
    vec2 A = as * vec2(0.0, 0.5);
    vec2 B = as * vec2(-1.0, -0.5);

    vec2 AP = P - A;
    vec2 AB = B - A;

    vec2 projection = A + dot(AP, AB) / dot(AB, AB) * AB / as;

    if(projection.x > -0.51 && projection.x < -0.49 && projection.y > -0.01 && projection.y < 0.01) {
        gl_FragColor = vec4(0.0, 0.0, 1.0, 1.0);
    } else {
        gl_FragColor = vec4(0.0, 1.0, 0.0, 1.0);
    }
}