是否有更优雅的方法通过AutoIt获得Internet Expolor版本

Question

摘要：

我正在寻找一种更优雅的方式来在Windows计算机上获取Internet Explorer（ IE ）版本（尤其是使用AutoIt，因为已编译* .exe）。我当前的解决方案（如下）可以完成这项工作，但是也许有更好的方法使用纯AutoIt函数（UDF）？

背景和目标：

我必须检查特定的 IE 版本，并且通常检查低于11（11.0.9600）的版本。

• information-about-internet-explorer-versions

我必须检查大约60台设备（服务器，笔记本电脑等）。编译后的* .exe将找到版本，并将该信息（除主机名等其他信息外）的条目设置为小型HTML报告。远程处理和执行不是问题。

代码：

#include-once
#include <Array.au3>

Func _getFileProperties( $sDirectory, $sFileName, $bRemoveEmptyLines = True )
    Local $oShellApp           = ObjCreate( 'Shell.Application' )
    Local $oFolder             = $oShellApp.NameSpace( $sDirectory )
    Local $oFolderItem         = $oFolder.Parsename( $sFileName )
    Local $aPropertyList[1][2] = [[1]]

    For $i = 0 To 400 Step 1
        If $oFolder.GetDetailsOf( $oFolder.Items, $i ) Then
            ReDim $aPropertyList[$aPropertyList[0][0] + 1][2]
            $aPropertyList[$aPropertyList[0][0]][0] = $oFolder.GetDetailsOf( $oFolder.Items, $i )
            $aPropertyList[$aPropertyList[0][0]][1] = $oFolder.GetDetailsOf( $oFolderItem, $i )
            $aPropertyList[0][0] += 1
        EndIf
    Next
    _ArraySort( $aPropertyList, 0, 1, 0 )

    If $bRemoveEmptyLines Then
        For $i = $aPropertyList[0][0] - 1 To 1 Step - 1
            If $aPropertyList[$i][1] == '' Then _ArrayDelete( $aPropertyList, $i )
        Next
    EndIf

    $aPropertyList[0][0] = UBound( $aPropertyList, 1 ) - 1
    Return $aPropertyList
EndFunc

Global $aPropertyList = _getFileProperties( @SystemDir, 'ieframe.dll' )
_ArrayDisplay( $aPropertyList )

当前结果：

我当然会根据搜索条件过滤数组（没问题）。

预期结果：

与上面的基本结果（当前结果）基本相同，但可能更快，并且还具有AutoIt自己的/本机功能？因为这只是将收集的许多其他信息的一个步骤，所以我尝试减少代码并提高以后编辑的可读性。

请注意，我可以检查
_getFileProperties( @SystemDir, 'ieframe.dll' )或
_getFileProperties( $sPathIe, 'iexplore.exe' )。
两者都提供版本信息。

还有另一种方式，更优雅和AutoIt自己的/本机功能来实现我的目标吗？

Answer 1

您也可以尝试检查注册表详细信息以验证IE版本。希望这可以帮助您找到其他方式。

;Internet Explorer version is
Global $svcVersion = (RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer", "svcVersion"))
If $svcVersion <> "" Then
    MsgBox(1, "internet Explorer Version" , "Internet Explorer version is: " & $svcVersion)
Endif

OR

;Internet Explorer updated version is
Global $svcUpdateVersion = (RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer", "svcUpdateVersion"))
If $svcUpdateVersion <> "" Then
    MsgBox(1, "internet Explorer Version" , "Internet Explorer updated version is: " & $svcUpdateVersion)
Endif