Question

我有这段代码试图显示求和；

0-100之间的所有偶数或用户输入的任何数字

然后；

显示0-100或用户输入的任何数字的所有奇数之和。

这是我到目前为止所拥有的：

Evennumber=InputBox("Please enter a even number!")

print "total + e"

For e= 2 to Evennumber step 2
  total= total+e
  print total&" +  "&e
Next

print total


Oddnumber=InputBox("Please enter a odd number!")
print "total + o"

For o= 1 to Oddnumber step 2
  total = total + o
  print total&" + "&o 
Next

print total

这正确吗？

Answer 1

关键是您在使用total之前未将其初始化为零。

Option Explicit
Dim e, o, Evennumber, Oddnumber, total

Evennumber = InputBox("Please enter a even number!")

MsgBox "total + e"

total = 0
For e = 2 to Evennumber step 2
  total= total+e
  MsgBox total & " +  " & e
Next
MsgBox total

Oddnumber = InputBox("Please enter a odd number!")
MsgBox "total + o"

total = 0
For o = 1 to Oddnumber step 2
  total = total + o
  MsgBox total & " + " & o 
Next
MsgBox total

Answer 2

@iBug's answer是正确的，但是它没有指出您应该遵循的关键编程原则，从长远来看将使您受益。此示例着重介绍DRY (Don't Repeat Yourself)，如果实施该重置，将会使total的重置为零。

选择数字和按值遍历数字的两个过程几乎相同。当您拥有这样的代码时，最好的方法是构建一个Function或Sub Procedure来处理逻辑，而无需将其重复。

下面，我们使用名为ProcessNumbers()的子过程，并通过少量的初始设置传递我们是希望偶数还是奇数，我们可以使用相同的函数来处理两组数字。

Option Explicit

'Even
Call ProcessNumbers(True)
'Odd
Call ProcessNumbers(False)

Sub ProcessNumbers(isEven)
  Dim i, startFrom, endAt, total, label
  Dim input, criteria

  If isEven Then 
    startFrom = 2
    endAt = 100
    label = "Even"
  Else
    startFrom = 1
    endAt = 100
    label = "Odd"
  End If
  input = InputBox("Please enter an " & label & " number!")
  If Len(input & "") > 0 And IsNumeric(input) Then endAt = CLng(input)
  For i = startFrom To endAt
    If isEven Then criteria = (i Mod 2 = 0) Else criteria = (i Mod 2 <> 0)
    If criteria Then
      total = total + i
      WScript.Echo total & " + " & i
    End If
  Next
  WScript.Echo total
End Sub

输出：

VBScript求和

2 个答案: