Question

我正在尝试编写一个函数，该函数计算一个邮政编码与另一个邮政编码之间的最小距离。该函数应输入一个邮政编码的经度和纬度，然后输入一个包含邮政编码的所有经度和纬度信息的二维数组。这是我编写的函数：

Public Function PassArray(Longitude As Double, Latitude As Double, ParamArray varValues() As Variant) As Double
    Dim arr() As Variant
    Dim x As Long
    For x = 1 To UBound(varValues(0), 1)
        ReDim Preserve arr(x)
        arr(UBound(arr)) = Sqr((Longitude - varValues(0)(x, 1)) ^ 2 + (Latitude - varValues(0)(x, 2)) ^ 2)
    Next x
    PassArray = WorksheetFunction.Min(arr)

尝试使用此功能时出现#Value!错误。我检查了每一步，似乎是UBound(varValues(0), 1)引起了问题。当我尝试UBound(varValues)时，它返回0，我猜这是参数数组的第一维上限吗？

我不明白为什么UBound(varValues(0), 1)无法正常工作。我以为它应该返回我的经度和纬度数组的最后一行数字。

Answer 1

考虑@Mathieu Guindon的评论，并遵循以下原则：

Option Explicit

'ASSUMPTION: coordinatesArray is a 2D array with rows in dimension 1 and columns in dimension 2.
Public Function PassArray(longitude As Double, latitude As Double, coordinatesArray As Variant) As Double
    Dim rowLowerBound As Long
    Dim rowUpperBound As Long
    Dim x As Long

    'We're looking at coordinatesArray's first dimension (rows).
    'Let's consider both the lower and upper bounds, so as to adapt to the
    'configuration of coordinatesArray.
    rowLowerBound = LBound(coordinatesArray, 1)
    rowUpperBound = UBound(coordinatesArray, 1)

    'Dim arr upfront; this will be way faster than redimming within the loop.
    ReDim arr(rowLowerBound To rowUpperBound) As Double

    For x = rowLowerBound To rowUpperBound
       'Your calculations go here.
       'You can access coordinatesArray elements like so:
       'coordinatesArray(x, 1) for row x, column 1, and
       'coordinatesArray(x, 2) for row x, column 2.
       arr(x) = Sqr((longitude - coordinatesArray(x, 1)) ^ 2 + (latitude - coordinatesArray(x, 2)) ^ 2)
    Next x

    'Note that Application.WorksheetFunction.Min doesn't seem to care
    'whether arr is zero, one or n-based.
    PassArray = Application.WorksheetFunction.Min(arr)
End Function

请注意，我不能保证您的距离计算；可能适用于笛卡尔坐标，但不适用于经度/纬度。

将UBound用于ParamArray时出现值错误

1 个答案: