Question

我有多个工作簿具有相同的列，并且我需要将其合并为一张工作表，并且其列名只能复制一次。找不到全面的解决方案。请帮助

Answer 1

请尝试以下操作，您将不得不根据需要进行调整。概括地说，您需要执行以下步骤

获取您拥有图纸的文件夹位置
使用特定名称等获取您感兴趣的xl文件
对于这些文件中的每个文件以及这些文件中的每个工作表 3a。将单元格复制到最后填充的行 3b。从第一行开始粘贴目标。
测试

Option Explicit
Sub LoopAllExcelflesInFolder()
    Dim wb As Workbook
    Dim target As Worksheet
    Dim flePath As String
    Dim fle As String
    Dim fleDlg As fleDialog
    Dim ws As Worksheet
    Dim firstEmptyRowTarget As Long
    Dim lastRowSource As Long
    Dim RangeToMove As Range

      Application.ScreenUpdating = False
      Application.EnableEvents = False
      Application.Calculation = xlCalculationManual

    'get folder loc from the user
      Set fleDlg = Application.fleDialog(msofleDialogFolderPicker)

        With fleDlg
          .Title = "Select A Target Folder"
          .AllowMultiSelect = False
            If .Show <> -1 Then GoTo nxt 'in case cancelled get to next block
            flePath = .SelectedItems(1) & "\"
        End With

nxt:
      flePath = flePath
      If flePath = "" Then GoTo closeandgo

      Set target = ActiveWorkbook.Sheets("Sheet1") 'change your target here

      fle = Dir(flePath & "*.xls*")
      LRDest = 1 '(assuming starting row is 1)
      Do While fle <> ""
          Set wb = Workbooks.Open(flename:=flePath & fle)
            '' for each worsheet , copy the contents / include your logic here if the sheet has a specific name/pattern etc. assuming the column headers are the same
            For Each ws In wb.Sheets
            lastRowSource = ws.Cells(ws.Rows.Count, 1).End(xlUp).Row ' find the last row in the source
            Set RangeToMove = ws.Range("A1:AJ" & LRSrc) 'Change the columns you want to copy here

            RangeToMove.Copy target.Cells(firstEmptyRowTarget, 1)

            firstEmptyRowTarget = target.Cells(target.Rows.Count, 1).End(xlUp).Row + 1 ''Save the last row in the target after copyin
            Next

          DoEvents

            'Get next fle name
          fle = Dir
      Loop


      MsgBox "done..."

closeandgo:
      'Reset Macro Optimization Settings
        Application.EnableEvents = True
        Application.Calculation = xlCalculationAutomatic
        Application.ScreenUpdating = True

End Sub

Answer 2

我偶尔看到这些类型的问题。您可以采用几种方法。尝试下面的代码，并了解您的情况。如有其他问题，请发回。

Sub Basic_Example_1()
    Dim MyPath As String, FilesInPath As String
    Dim MyFiles() As String
    Dim SourceRcount As Long, Fnum As Long
    Dim mybook As Workbook, BaseWks As Worksheet
    Dim sourceRange As Range, destrange As Range
    Dim rnum As Long, CalcMode As Long

    'Fill in the path\folder where the files are
    MyPath = "C:\Users\Ron\test"

    'Add a slash at the end if the user forget it
    If Right(MyPath, 1) <> "\" Then
        MyPath = MyPath & "\"
    End If

    'If there are no Excel files in the folder exit the sub
    FilesInPath = Dir(MyPath & "*.xl*")
    If FilesInPath = "" Then
        MsgBox "No files found"
        Exit Sub
    End If

    'Fill the array(myFiles)with the list of Excel files in the folder
    Fnum = 0
    Do While FilesInPath <> ""
        Fnum = Fnum + 1
        ReDim Preserve MyFiles(1 To Fnum)
        MyFiles(Fnum) = FilesInPath
        FilesInPath = Dir()
    Loop

    'Change ScreenUpdating, Calculation and EnableEvents
    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    'Add a new workbook with one sheet
    Set BaseWks = Workbooks.Add(xlWBATWorksheet).Worksheets(1)
    rnum = 1

    'Loop through all files in the array(myFiles)
    If Fnum > 0 Then
        For Fnum = LBound(MyFiles) To UBound(MyFiles)
            Set mybook = Nothing
            On Error Resume Next
            Set mybook = Workbooks.Open(MyPath & MyFiles(Fnum))
            On Error GoTo 0

            If Not mybook Is Nothing Then

                On Error Resume Next

                With mybook.Worksheets(1)
                    Set sourceRange = .Range("A1:C1")
                End With

                If Err.Number > 0 Then
                    Err.Clear
                    Set sourceRange = Nothing
                Else
                    'if SourceRange use all columns then skip this file
                    If sourceRange.Columns.Count >= BaseWks.Columns.Count Then
                        Set sourceRange = Nothing
                    End If
                End If
                On Error GoTo 0

                If Not sourceRange Is Nothing Then

                    SourceRcount = sourceRange.Rows.Count

                    If rnum + SourceRcount >= BaseWks.Rows.Count Then
                        MsgBox "Sorry there are not enough rows in the sheet"
                        BaseWks.Columns.AutoFit
                        mybook.Close savechanges:=False
                        GoTo ExitTheSub
                    Else

                        'Copy the file name in column A
                        With sourceRange
                            BaseWks.cells(rnum, "A"). _
                                    Resize(.Rows.Count).Value = MyFiles(Fnum)
                        End With

                        'Set the destrange
                        Set destrange = BaseWks.Range("B" & rnum)

                        'we copy the values from the sourceRange to the destrange
                        With sourceRange
                            Set destrange = destrange. _
                                            Resize(.Rows.Count, .Columns.Count)
                        End With
                        destrange.Value = sourceRange.Value

                        rnum = rnum + SourceRcount
                    End If
                End If
                mybook.Close savechanges:=False
            End If

        Next Fnum
        BaseWks.Columns.AutoFit
    End If

ExitTheSub:
    'Restore ScreenUpdating, Calculation and EnableEvents
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .Calculation = CalcMode
    End With
End Sub

https://www.rondebruin.nl/win/s3/win008.htm

复制多个工作簿并粘贴到一张纸中

2 个答案: