Question

我有类型定义：

type FsTree = Node of (string * FsTree) list

我创建一个空节点：

let createEmptyFsTree () : FsTree = Node[]

我想从字符串列表的路径构建树，例如：

let fs1 = create ["MainNode";"nodeA";"nodeB"] (createEmptyFsTree())
let fs2 = create ["MainNode";"nodeC";"nodeD"] fs1
let fs3 = create ["MainNode";"nodeC";"nodeE"] fs2

结果将是：

Node [("MainNode", Node [

                             ("nodeA", Node [("nodeB", Node [])]);
                             ("nodeC", Node [
                                         ("nodeD", Node[]);
                                         ("nodeE", Node[])])])]

到目前为止，这是我的代码。我被困了2天。请帮忙。

let create (p : string list) (fs : FsTree) =
        let rec create (p : string list) (fs : FsTree) =
            match fs with 
            | Node n -> match p, n with
                        | h :: t, (name, rsNode) :: rsTree when name = h -> Node([(h, (create t rsNode))] @ rsTree)
                        | _, lNode :: rsTree -> Node([lNode]@rsTree)
                        | h :: t, [] -> Node ([h, (create t (createEmptyFsTree()))])
                        | [],[] -> Node[]
        create p fs

我只能从第一个通过的路径创建树：

Node [("MainNode", Node [("nodeA", Node [("nodeB", Node [])])])]

Answer 1

此问题的难点在于，需要依次递归遍历多个结构（路径是list，每个节点是list和子树）为它工作。仅凭一种功能很难做到这一点。

这就是为什么我喜欢通过将问题分解成更小的部分来简化问题。在这里，我们将使用2个相互递归的函数（注意语法）。首先，我将重命名功能，以便我更好地了解它们的作用。我还避免为函数和变量重复相同的名称，因为这会造成混淆。我的第一个函数将仅处理遍历路径p：

let rec addPath (p : string list)   (Node ns) =
    match p with
    | []       -> Node                    ns
    | hp :: tp -> Node (addHeadPath hp tp ns)

我在第二个参数(Node ns)上使用模式匹配来获取子节点列表，这是因为下一个函数将遍历该列表。

在我的match表达式中，我喜欢照顾空列表的情况，即递归的结束。第二种情况将头和尾分开，并将它们发送到另一个函数来处理：

and addHeadPath hp tp ns =
    match ns with
    | []                          -> [hp, addPath tp (Node[]) ]
    | (nn, st) :: tn when nn = hp -> (nn, addPath tp st       ) ::                   tn
    | hn       :: tn              -> hn                         :: addHeadPath hp tp tn

addHeadPathTo与addPathTo是相互递归的，因此我将它们与and而不是另一个let rec绑定在一起。

同样，首先处理空的情况，该情况返回具有一个节点的列表，并调用addPathTo以添加其余路径。第二种情况是当节点已经存在时，在这种情况下，我们将其余路径添加到子树st中。第三种情况通过递归调用自身来不断查看节点列表。

您可以通过以下方式调用它：

createEmptyFsTree()
|> addPath ["MainNode";"nodeA";"nodeB"] 
|> addPath ["MainNode";"nodeC";"nodeD"]
|> addPath ["MainNode";"nodeC";"nodeE"]    
|> printfn "%A"

从f＃中的字符串列表的给定路径创建树

1 个答案: