Question

我有下表：

t:([]sym:`eae`oco`khd`dga`eob`iog`edg`kio`gme`iko; val:1 0 5 1 0 0 1 7 6 3)

sym val
-------
eae 1  
oco 0  
khd 5  
dga 1  
eob 0  
iog 0  
edg 1  
kio 7  
gme 6  
iko 3

我要根据以下规则分配一些bucket值：

if 0 <= val < 1, then bucket = 3 
if 1 <= val < 3, then bucket = 8
if 3 <= val < 5, then bucket = 20
if 5 <= val    , then bucket = 30

类似于将步进函数应用于值val。结果表应如下所示：

sym val bucket
--------------
eae 1   8     
oco 0   3     
khd 5   30    
dga 1   8     
eob 0   3     
iog 0   3     
edg 1   8     
kio 7   30    
gme 6   30    
iko 3   20

当然，我不想申请if[if[...]]，我正在寻找一种优雅的q-ist解决方案。

Answer 1

以下作品：

update bucket: (`s#0 1 3 5!3 8 20 30)[val] from t

Answer 2

尽管我更喜欢@Anonymouse的逐步函数字典方法，但出于完整性考虑，另一种方法是使用asof连接

q)aj[`val;t;([]val:0 1 3 5;bucket:3 8 20 30)]
sym val bucket
--------------
eae 1   8
oco 0   3
khd 5   30
dga 1   8
eob 0   3
iog 0   3
edg 1   8
kio 7   30
gme 6   30
iko 3   20

Answer 3

此功能称为“阶梯式字典”。尽管@Anonymouse已经介绍了使用它的字典方式，但是，通过将其转换为阶梯式keyed-table，还有一种稍微不同的使用方式。这将使使用lj与任何其他表的联接变得更容易：

q)t:([]sym:`eae`oco`khd`dga`eob`iog`edg`kio`gme`iko; val:1 0 5 1 0 0 1 7 6 3)
q)sd:`s#([val:0 1 3 5] bucket:3 8 20 30)
q)t lj sd

将阶跃函数应用于值

3 个答案: