Question

我们有一个在线平台，我们在后端使用maxima对学生给出的答案提供反馈。

说多项式长除法的解是以下函数：

sol: 3+(2+4*x)/(3*x^2+2*x+8);

假设学生给出答案：

ans: 3 +(3-5*x)/(3x^2+2*x+8)

然后，我们希望提供大致的反馈意见。

您的答案确实具有以下形式：



常数s是正确的，但是您没有选择正确的线性函数r（x）。

我尝试通过以下方式实施此反馈：

ans: 3 +(3-5*x)/(3x^2+2*x+8);
remvalue(a,b,c,d);
matchdeclare([a,b,c,d], constantp);
defmatch(match, d+ (a*x+b)/(3*x^2+2*x+8));
match(ans);

但是，defmatch似乎无法匹配它。我还可以使用其他函数来匹配商函数吗？

它确实可以在更简单的情况下工作：

ans: (3-5*x)/(3*x^2+2*x+8); 
remvalue(a,b,c);
matchdeclare([a,b,c], constantp);     
defmatch(match, (a*x+b)/(3*x^2+2*x+8));     
match(ans);

Answer 1

如果问题全部是多项式除法，则可以使用divide函数返回商和余数，然后验证学生的输入是否与商+余数/除数相同。

对于匹配商+余数/除数，defmatch可能不够强大，因为它主要是（尽管不是全部）寻找形式匹配，并且在许多情况下，它无法检测到等效但形式上不同。

让我考虑一下如何实现此问题的匹配功能。也许其他人也有建议。

编辑：这是匹配此类表达式的一种方法。我将多项式的比率与其他术语分开。如果存在一个比率项，而所有其他项都是多项式，则您要匹配的模式将得到匹配。

我已经利用了至少一种晦涩但有用的甚至是可理解的"+"表达式匹配功能。由于"+"是可交换的，因此模式匹配器会清除与尝试的第一个谓词匹配的所有参数，然后清除第二个谓词，因此，如果有两个以上的预测。如果声明了任何模式匹配变量来匹配all，则它匹配所有参数，并且不存在任何参数。模式变量将以相反的顺序尝试，因此aa将最后处理。效果是将"+"表达式划分为匹配陈述谓词和其他所有内容的术语。在%i7中使用。

(%i2) matchdeclare (pp, lambda ([e], polynomialp (e, [pvar]))) $
(%i3) matchdeclare (qq, lambda ([e], diff (e, pvar) # 0 and polynomialp (e, [pvar]))) $
(%i4) defmatch (match_pratio, pp/qq, pvar) $
(%i5) matchdeclare (aa, all) $
(%i6) matchdeclare (rr, lambda ([e], match_pratio (e, pvar) # false)) $
(%i7) defmatch (match_pratio_plus_remainder, rr + aa, pvar) $
(%i8) match_foo (e, pvar) := 
  block ([aa, pp, qq, rr],
    if match_pratio (e, pvar) # false
      then [0, pp, qq, pp/qq]
    elseif match_pratio_plus_remainder (e, pvar) # false
      then if polynomialp (aa, [pvar]) and op(rr) # "+"
        then [aa, pp, qq, rr]) $

以下是一些匹配的示例：

(%i9) match_foo (u^2/2 - 3*u + 1 + (u - 1)/(u^2 + u - 1), u);
            2
           u                     2            u - 1
(%o9)     [-- - 3 u + 1, u - 1, u  + u - 1, ----------]
           2                                 2
                                            u  + u - 1
(%i10) match_foo (u^2/2 - 3*u + 1 - 2*(u - 1)/(u^2 + u - 1), u);
         2
        u                           2            2 (u - 1)
(%o10) [-- - 3 u + 1, - 2 (u - 1), u  + u - 1, - ----------]
        2                                         2
                                                 u  + u - 1
(%i11) match_foo (u^2/2 - 3*u + 1 - 2/(u^2 + u - 1), u);
            2
           u                   2                2
(%o11)    [-- - 3 u + 1, - 2, u  + u - 1, - ----------]
           2                                 2
                                            u  + u - 1
(%i12) match_foo (1 - 2/(u^2 + u - 1), u);
                         2                2
(%o12)         [1, - 2, u  + u - 1, - ----------]
                                       2
                                      u  + u - 1
(%i13) match_foo (- 2/(u^2 + u - 1), u);
                         2                2
(%o13)         [0, - 2, u  + u - 1, - ----------]
                                       2
                                      u  + u - 1

这里有一些不匹配的示例：两个多项式比率项，无多项式比率和一个非多项式项。

(%i14) match_foo (1/u - 2/(u^2 + u - 1), u);
(%o14)                        false
(%i15) match_foo (1 - (u^2 + u - 1)/2, u);
(%o15)                        false
(%i16) match_foo (sin(u) - 2/(u^2 + u - 1), u);
(%o16)                        false

第二编辑：我想我把match_pratio_plus_remainder的名字改错了，应该是match_remainder_plus_quotient。哦，很好。

最大值中的匹配商函数

1 个答案: